主页 / unix / 问题 / 788816
Accepted
An5Drama
Asked: 2024-12-29 12:35:54 +0800 CST

如何在 awk 中突出显示由多个用 `||` 断开的正则表达式表达式得到的匹配的正则表达式模式？

  • 772

grep这个高亮功能可以在中轻松实现--color。但grep 不能同时进行正则匹配和反匹配，例如grep foo -v bar ...（我需要这个功能，因为--color只能在管道的初始输入时使用|，因此后者的 grep 将使用该彩色结果，这使得grep foo --color=always ... | grep -v "foo bar"不会删除那些带有“foo bar”的行）。

因此我使用了awk上述链接提示，但它缺少突出显示功能。我们可以使用 和 提取正则表达式结果match，substr其中我们将正则表达式模式包装在 中match。然后我们可以通过仅使用ANSI 颜色代码/\<no issue\>/突出显示正则表达式结果。printf substr($0,1,RSTART-1) "\033[1;31m" substr($0,RSTART,RLENGTH) "\033[0m: " substr($0,RSTART+RLENGTH) "\n"

问：

但match对于参考链接中由正则表达式构建的布尔表达式不起作用/foo/ && !/bar/。有没有一种优雅的解决方法（也许使用其他工具）？

我想到了一个临时的解决方法/foo/ && !/bar/{match($0,/foo/); printf ...}，但这会执行两次正则表达式。

我的预期行为（这里 0.“TODO”最多可以在一行中出现一次 1.我用来*...*显示要突出显示的内容 2.我只考虑/pattern1/ && !/pattern_included_totally_by_pattern1/，因此/foo/ && !/o/不考虑Ed Morton提供的。这就像grep逻辑，我首先grep一些，然后在从前一个grep执行中获得的那些结果中进行grep）：

# fail
$ echo "TODO foo\nTODO" | grep TODO --color=always | grep -v "TODO foo"
*TODO* foo
*TODO*
# expected
$ echo "TODO foo\nTODO" | awk -v RED="\033[1;31m" -v RESET="\033[0m" '/TODO/ && !/TODO foo/ {match($0,/TODO/); printf substr($0,1,RSTART-1) RED substr($0,RSTART,RLENGTH) RESET substr($0,RSTART+RLENGTH) "\n"}'
*TODO*
shell

3 个回答

  1. 我会perl在这里使用。突出显示foo不包含的行foo bar：

    perl -pe 's/foo/\e[31;1m$&\e[m/g unless /foo bar/' < your-file

    相同如下：

    awk '! /foo bar/ {gsub(/foo/, "\33[1;31m&\33[m")}; {print}' < your-file

    或者（假设 shell 支持 ksh93 风格$'...'的引号形式）：

    sed $'/foo bar/! s/foo/\e[1;31m&\e[m/g' < your-file

    或者突出显示foo后面没有 的 s bar。

    perl -pe 's/foo(?! bar)/\e[31;1m$&\e[m/g' < your-file

    不awk，sed等效的，除非你的sed是少数支持 perl 正则表达式的库之一-P（如 ast-open 的）或-R（如ssed）），但是更常见的是实现通常使用选项grep来支持-like 正则表达式，就像 GNU通过 PCRE2 库（以前称为 PCRE）构建类似 perl 的正则表达式支持时一样，在这种情况下你可以执行以下操作：perl-Pgrep

    grep -P --color 'foo(?! bar)' < your-file

    但这也会丢弃不匹配的行。

    要丢弃包含 的行并突出显示剩余行中foo bar的出现，您可以执行以下操作：foo

    perl -ne 'unless (/foo bar/) {
            s/foo/\e[31;1m$&\e[m/g;
            print
          }' < your-file

    或者：

    awk '! /foo bar/ {gsub(/foo/, "\33[1;31m&\33[m"); print}' < your-file

    或者（假设 shell 支持 ksh93 风格$'...'的引号形式）：

    sed  $'/foo bar/d; s/foo/\e[1;31m&\e[m/g' < your-file

    但你也可以这样做：

    < your-file grep -v 'foo bar' |
  grep --color -e '^' -e foo

    （-e '^'匹配所有行，所以它们不会被丢弃，-e foo以突出显示foo这些行中的出现；< file.in A | B > file.out就像A < file.in | B > file.out或A < file.in | > file.out B因为重定向可以在命令行的任何位置出现，但在管道中使用前者很常见，因为它使流程更加明显）。

    丢弃所有包含foo bar和不包含的行foo并突出显示foo剩余的行：

    perl -ne 'print if ! /foo bar/ && s/foo/\e[1;31m$&\e[m/g' < your-file

    sed -n $'/foo bar/! s/foo/\e[1;31m&\e[m/gp' < your-file

    awk '! /foo bar/ && gsub(/foo/, "\33[1;31m&\33[m")' < your-file

    < your-file grep -v 'foo bar' | grep --color foo

    有关语法的详细信息perl：

    • perl -p是sed模式（和perl -n模式sed -n），其中代码（此处以内联-e表达式的形式提供，如 中sed）针对输入的每一行运行，当前行为 中$_（相当于的模式空间，sed不同之处在于 中确实包含行分隔符）。请参阅了解详情。perl$_perldoc perlrun
    • s/replacement/replacement/与 类似sed，但有很多改进，特别是功能更齐全的正则表达式，许多其他语言都已效仿。
    • (?! foo)是 perl 引入的额外正则表达式运算符之一，它是一个负向预测运算符。请参阅perldoc perlre了解详情。
    • code unless some-condition是 的缩写形式unless (some-condition) {code}，读起来更像英语，但其他方面相同。unless就像if !。perldoc perlsyn详情请参阅。
    • 2
  2. Best Answer

    您的解决方法完全可以接受。请注意，由于您似乎正在使用 gnu awk，因此您还可以使用sub()或 gsub()将正则表达式替换为字符串，并将&其替换为匹配的部分：

    /foo/ && !/bar/ {
  sub(/foo/, "\033[1;31m" "&" "\033[0m: ")  # changes $0
  print
}

    如果你不想重复正则表达式，你可以将测试拆分开

    !/bar/{ if(/foo/){ sub(...); print } }

    或者因为sub()成功时返回 1

    !/bar/{ if(sub(/foo/, ...)) print }

    或者

    !/bar/ && sub(/foo/, ...) { print }
    • 2

  3. 有时在您的问题中，听起来您想突出显示满足条件的整行，/foo/ && !/bar/这只是（根据需要使用颜色代码替换）RED：RESET

    awk '/foo/ && !/bar/ { print "RED" $0 "RESET" }'

    而在其他时候，听起来您想突出显示匹配foo但不foo bar匹配的行：

    awk '/foo/ && !/foo bar/ { print "RED" $0 "RESET" }'

    或者为了避免写foo两次：

    awk 'match($0,/foo/) && (substr($0,RSTART+RLENGTH) !~ / bar/) {
    print "RED" $0 "RESET"
}'

    而在其他时候，听起来你只想突出显示在不包含以下内容foo的行上匹配的部分：bar

    awk '!/bar/ && match($0,/foo/) {
    print substr($0,1,RSTART-1) "RED" substr($0,RSTART,RLENGTH) "RESET" substr($0,RSTART+RLENGTH)
}'

    如果您想要与上述两种方法不同的方法，请在您的问题中展示一个例子。特别是，如果您正在寻找一种通用解决方案，可以在复合条件中给定多个正则表达式来突出显示行的部分内容，请在您的问题中解释突出显示和不突出显示的内容背后的逻辑，包括这种情况/foo/ && !/o/。

    • 2

相关问题