主页 / unix / 问题 / 793509
Accepted
Ahmad Ismail
Asked: 2025-04-09 18:25:23 +0800 CST

光标停在单引号和双引号处

  • 772

我有一个像这样的zle：

function _ctrl-shift-left() {
    ((REGION_ACTIVE)) || zle set-mark-command # Selection
    zle backward-word
}

zle -N _ctrl-shift-left
bindkey '^[[1;6D' _ctrl-shift-left # Ctrl+Shift+Left to select till the beginning of the previous word.

例如下面的命令

$ curl -s "https://samplesite.com/101146/07/data-processing/13/?#/101146-132519042909.html" | grep -oP 'https://dl\d*\.samplesite\.com/Files/[^"]+\.rar' | sed 's/\?nocache=[^&]*//g'

当我按下时ctrl-shift-left，我想将光标停在'和处"。

我怎样才能做到这一点？

zsh

2 个回答

  1. Best Answer

    默认情况下，对于backward-word所有单词运动/动作小部件，单词都是字母数字字符加上中的字符$WORDCHARS（类似于$wordcharstcsh 的），但您也可以使用select-word-style自动加载功能来更改单词的定义。

    autoload -Uz select-word-style
select-word-style shell

    将会改变单词的定义：

    shell
    单词是完整的 shell 命令参数，可能包括完整的引用字符串，或任何 shell 特殊的标记。

    所以在你的

    $ curl -s "https://samplesite.com/101146/07/data-processing/13/?#/101146-132519042909.html" | grep -oP 'https://dl\d*\.samplesite\.com/Files/[^"]+\.rar' | sed 's/\?nocache=[^&]*//g'
  ⇑    ⇑  ⇑                                                                                 ⇑ ⇑    ⇑   ⇑                                                 ⇑ ⇑   ⇑

    backward-word将带您前往上面标有的地方⇑。

    这不完全是你想要的，因为它不会停止，"但[^"]我怀疑这可能是你真正想要的。

    还可以使用该select-word-style函数制作一个小部件并将其绑定到某些组合键以交互方式选择单词样式：

    autoload -Uz select-word-style
zle -N select-word-style
bindkey '\ez' select-word-style

    然后按Alt+z将显示此提示：

    $
Word styles (hit return for more detail):
(b)ash (n)ormal (s)hell (w)hitespace (d)efault (q)uit
(B), (N), (S), (W) as above with subword matching
?

    更多详细信息：

    $
Word styles (hit return for more detail):
(b)ash (n)ormal (s)hell (w)hitespace (d)efault (q)uit
(B), (N), (S), (W) as above with subword matching
(b)ash:       Word characters are alphanumerics only
(n)ormal:     Word characters are alphanumerics plus $WORDCHARS
(s)hell:      Words are command arguments using shell syntax
(w)hitespace: Words are whitespace-delimited
(d)efault:    Use default, no special handling (usually same as `n')
(q)uit:       Quit without setting a new style

    或者，您可以指定在 zle 小部件shell的上下文中使用 word-style _ctrl-shift-left：

    zstyle :zle:_ctrl-shift-left word-style shell

    或者可能更接近你的要求：

    zstyle :zle:_ctrl-shift-left word-style unspecified
zstyle :zle:_ctrl-shift-left word-chars \'\"

    仅跳转到'和"字符。

    • 1

  2. 楼主在这里。与此同时，我已经想出了一个解决方案，如何使用“如何让 zsh vi 风格的命令尊重 WORDCHARS？”

    代码如下：

    SEPCHARS="[ '\"]"

my-forward-word() {
    if [[ "${BUFFER[CURSOR + 1]}" =~ "${SEPCHARS}" ]]; then
        (( CURSOR += 1 ))
        return
    fi
    while [[ CURSOR -lt "${#BUFFER}" && ! "${BUFFER[CURSOR + 1]}" =~ "${SEPCHARS}" ]]; do
        (( CURSOR += 1 ))
    done
}

zle -N my-forward-word

my-backward-word() {
    if [[ "${BUFFER[CURSOR]}" =~ "${SEPCHARS}" ]]; then
        (( CURSOR -= 1 ))
        return
    fi
    while [[ CURSOR -gt 0 && ! "${BUFFER[CURSOR]}" =~ "${SEPCHARS}" ]]; do
        (( CURSOR -= 1 ))
    done
}

zle -N my-backward-word
    • 0

相关问题