主页 / unix / 问题 / 784925
Accepted
Benjam1n
Asked: 2024-10-11 23:17:13 +0800 CST

如何在特定匹配 + 偏移后替换字符？

  • 772

我有一个文件，其中包含必须隐藏的值（替换为 XX），但它们在整行中并不总是位于同一位置，而且我不知道它们的内容。但我知道的是它们相对于特定匹配项的位置。

例如，我想将“00 00”后的第三和第四个数字替换为XX

原来的：

AA BB CC 00 00 01 02 03 04 05 06 07
AA BB CC DD EE FF 00 00 08 09 10 11 12 13 14

期望输出：

AA BB CC 00 00 01 02 XX XX 05 06 07
AA BB CC DD EE FF 00 00 08 09 XX XX 12 13 14

我尝试使用 awk，但只能定位到行首。例如，有没有办法从特定匹配中索引 $2 和 $3？

编辑：该行中只能出现一次00 00，它不能包含00 00 00无需担心前导或尾随匹配。

我迄今为止的（令人尴尬的）尝试是：

cat file | awk -F'00 00' '{print $2}' | awk '{gsub ($3,"XX",$0);gsub ($4,"XX",$0)}1'

除了多个 awk 之外，我还丢失了行的开头，因为匹配项之前的所有内容都被我的第一个 awk 删除了

awk

4 个回答

  1. Best Answer

    sed使用或perl比使用更容易，awk除非您有一个awk支持 的gawk扩展gensub()名：

    sed 's/\(00 00 .. .. \).. ../\1XX XX/' < file

    perl -pe 's/00 00 .. .. \K.. ../XX XX/' < file

    gawk '{print gensub(/(00 00 .. .. ).. ../, "\\1XX XX", 1)}' < file

    使用 POSIX awk，您可以执行以下操作：

    awk '
  match($0, /00 00 .. .. .. ../) {
    $0 = substr($0, 1, RSTART+11) "XX XX" substr($0, RSTART+RLENGTH)
  }
  {print}' < file
    • 5

  2. 这是一个 awk 方法：

    $ awk '
{ 
  for(i=1; i<=NF; i++){ 
    if($i=="00" && $(i+1)=="00"){
      $(i+4)=$(i+5)="XX"
    }
  }
}1' file 
AA BB CC 00 00 01 02 XX XX 05 06 07
AA BB CC DD EE FF 00 00 08 09 XX XX 12 13 14

    这个想法是遍历所有字段（for(i=1; i<=NF; i++)；NF是字段数），并查找当前字段（$i）和下一个字段（$(i+1)）都设置为字符串的情况00。然后，我们将第 3 和第 4 个字段更改为XX（$(i+4)=$(i+5)="XX"；使用+4和，+5因为我从第一个 开始计算00，而不是第二个）。最后，我们打印所有内容。当表达式求值为真时，默认操作awk是打印该行，因此简单的1（始终为真）通常用作 的简写print。

    请注意，这样做的缺点是将字段分隔符替换为空格。在此示例中，这似乎不是问题，但如果是问题，只需指定输入和输出分隔符即可。因此，如果您的输入中有要保留的逗号，您可以执行以下操作：

    $ cat file 
AA,BB,CC,00,00,01,02,03,04,05,06,07
AA,BB,CC,DD,EE,FF,00,00,08,09,10,11,12,13,14

$ awk -F',' -v OFS=',' '
{ 
  for(i=1; i<=NF; i++){ 
    if($i=="00" && $(i+1)=="00"){
      $(i+4)=$(i+5)="XX"
    }
  }
}1' file 
AA,BB,CC,00,00,01,02,XX,XX,05,06,07
AA,BB,CC,DD,EE,FF,00,00,08,09,XX,XX,12,13,14

    您也可以将其视为一个简单的替换并执行以下操作：

    $ sed -E 's/( 00 00 .. ..) .. ../\1 XX XX/' file 
AA BB CC 00 00 01 02 XX XX 05 06 07
AA BB CC DD EE FF 00 00 08 09 XX XX 12 13 14

    或者

    $ perl -pe 's/( 00 00 .. ..) .. ../$1 XX XX/' file 
AA BB CC 00 00 01 02 XX XX 05 06 07
AA BB CC DD EE FF 00 00 08 09 XX XX 12 13 14
    • 2

  3. 使用awk：

    $ awk 'match($0, /(00 ){2,}[0-9]+ [0-9]+/){ 
     len=RSTART+RLENGTH;
     printf "%s",substr($0,1,len);
     $0=substr($0,len+1);
     sub(/[0-9]+ [0-9]+/, "XX XX");}1'

    假设之后只有数字重复00 00。

    该命令使用gawk的拆分功能。

    $ awk -v var="XX XX"  '
   n=split($0,a, /00 00 .. .. .. ../, seps){
   $0="";
   sub(/.. ..$/, var,seps[1]);
   for(i=1;i<=n;i++)  $0 = $0 seps[i-1] a[i]}1'

    首先，当前记录（$0）为split。此内置函数创建两个数组，即a和seps（分隔符数组）。然后$0将设置为""。然后sub()用于var替换数组中要替换的字段seps。

    该命令通过的内置函数awk来拆分字段。GNU awksplit

    n = 拆分（s，数组，sep）

    将字符串s拆分为array[1] , ..., array[n]。返回找到的元素数。如果提供了sep参数，则将其用作字段分隔符；否则使用FS 。

    来自 Awk — 一种模式扫描和处理语言

    split(字符串，数组[，fieldsep [，seps]] )

    将字符串分成由fieldsep分隔的片段，并将片段存储在数组中，将分隔符字符串存储在seps数组中。

    摘自Arnold Robbins 所著的《有效的 AWK 编程》 。

    • 2

  4. 使用任何 awk：

    $ awk 's=index($0,"00 00") {$0=substr($0,1,s+11) "XX XX" substr($0,s+17)} 1' file
AA BB CC 00 00 01 02 XX XX 05 06 07
AA BB CC DD EE FF 00 00 08 09 XX XX 12 13 14
    • 2

相关问题