主页 / unix / 问题 / 784445
Accepted
dajoto
Asked: 2024-10-03 18:20:07 +0800 CST

ZSH 函数输出到当前提示输入被忽略

  • 772

我在 ZSH 中注册了一个函数，该函数会在当前路径下搜索文件内容以查找匹配项，然后捕获结果文件名。然后将其绑定到组合键。键绑定、搜索和结果都正常工作（因为它们返回所需的值）。

当我使用键绑定时，该值会打印到当前 shell 行，但不会被识别为实际输入（即，如果我按 Enter 键，该值将被视为空，并且不会向提示历史记录添加任何内容）。我如何输出结果，就好像它是输入的并且是有效值一样。我尝试过echo/ print/ printf（假设每个结果都相同），但也附加到BUFFER并设置CURSOR。

我确信这有充分的记录，但由于缺乏正确的术语，我找不到示例。有人能给我指出正确的方向吗？

zsh

2 个回答

  1. Best Answer

    打印到终端帮不了你。这会向用户显示一条消息（它不会出现在屏幕上的正确位置，并且会使行编辑器感到困惑，因为它会更改终端的光标位置 — 请使用zle -M或zle -R代替）。这不是 shell 的输入。

    magic 变量BUFFER包含用户正在编辑的行，并CURSOR包含输入光标位置。您可以通过修改BUFFER和来更改用户输入缓冲区和光标位置CURSOR。所以你走在正确的轨道上。不过，要在光标处插入某些内容，有一种更简单的方法：只需附加到 magic 变量LBUFFER，zsh 将完成剩下的工作。LBUFFER包含光标前的用户输入，并且可以直观地对其进行修改。

    下面是我.zshrc将命令的输出插入到输入缓冲区的一个工作示例。当我按下Alt+时，它会插入当前的 Git 分支名称v b。

    vc_insert_branch () {
  LBUFFER+=$(git symbolic-ref --short HEAD 2>/dev/null)
}
zle -N vc_insert_branch
bindkey '^[vb' vc_insert_branch

    请注意，这个简单示例按原样插入命令的输出。对于文件名，您可能应该用引号括起来，以防它包含特殊字符。例如，如果命令的输出是，A Song.mp3则上面的简单代码只会插入A Song.mp3命令行。但为了使其有用，它应该插入一些对命令有效的参数。如有必要，请使用q-或q+ 参数扩展标志引用命令的输出。

    insert_file_search_result () {
  LBUFFER+=${(q-)$(search command goes here 2>/dev/null)}
}

    请注意，如果您想根据光标周围的单词进行搜索，zsh 具有辅助函数，可让您免于自己进行命令行解析，并且它们还可以负责注入新文本。特别是，modify-current-argument用您选择的新 shell 单词替换光标周围的 shell 单词，并在必要时引用该单词。这是一个概念验证，展示了如何用包含该单词的最新文件替换光标所在的单词。

    function grep_word_and_reply_with_file_name {
  if [[ -z $ARG ]]; then
    zle -M 'Cursor not in a word'
    return 1
  fi
  local -a files
  files=(${(@0)${$(grep -l -Z -F -e $ARG -- /dev/null *(-.DNom))%$'\000'}})
  if (($#files == 0)); then
    zle -M "No match for $ARG"
    return 1
  fi
  REPLY=$files[1]
}

function grep_word_and_replace_with_file_name {
  autoload -Uz modify-current-argument
  modify-current-argument grep_word_and_reply_with_file_name
}
zle -N grep_word_and_replace_with_file_name
bindkey '\eG' grep_word_and_replace_with_file_name
    • 2

  2. 通常我会在接下来看到的事物中找到答案。

    我从https://github.com/junegunn/fzf/blob/master/shell/key-bindings.zsh中获得了一些灵感- 特别是fzf-history-widget函数。它LBUFFER使用用户输入（如果不是修订历史命令）设置变量，然后调用zle reset-prompt。我用我的BUFFER+CURSOR方法测试了这一点，它也有效，但该LBUFFER方法更简洁。

    • 0

相关问题