主页 / unix / 问题 / 780974
Accepted
Tyler Durden
Asked: 2024-07-29 00:10:33 +0800 CST

如何让新插入的设备被 ls（目录列表）识别？

  • 772

我使用 Arch Linux，我发现如果我将 USB 驱动器插入计算机，它不会显示在 中/run/media/user-name。但是，如果我使用 caja，我可以看到驱动器并查看其内容。然后，如果我返回命令行并运行ls /run/media/user-name它，它就会显示出来。

这是因为 caja 正在安装驱动器还是其他原因？我如何才能轻松地从命令行执行此操作？我的意思是我知道如何安装东西，但这很麻烦，因为您必须查找设备名称等。有没有一种简单的方法可以识别设备（除了在 caja 中查看它）？

arch-linux

1 个回答

  1. Best Answer

    这是因为 caja 正在安装驱动器还是别的什么？

    caja 向你的系统询问要安装的东西，是的。

    如何从命令行轻松地完成此操作。

    udisksctl mount -b /dev/something如果您已经知道存储设备的名称。如果不知道，您可以轻松找出出现的最新设备，ls -lt /dev/block/将首先为您提供最新的设备。

    您可以使用 卸载udisksctl unmount -b /dev/something。

    桌面环境与此不同的是，它有一个守护进程，当插入新的 USB 设备时，它会主动监听系统中交换的事件，因此此检测步骤在后台进行，并且设备会自动出现在 caja 中。它会根据udiskscaja 的请求进行安装，即您单击它时（而不是更早）。

    您可以围绕 caja 使用的相同功能构建一个简洁的小助手，以便您可以使用我为您编写的 zsh 脚本从终端挂载东西：

    #!/usr/bin/zsh
# Copyright 2024 Marcus Müller
# Licensed under EUPL-1.2
# 
# Script to show all block devices added the last 10 minutes
# Needs ZSH to be installed.

#                        /---- (…): "glob specifier"
#                        |/---   N: don't error if there's NO matching device
#                        ||
#                        ||  /--  c: created since…
#                        |/  |/-  m: in minutes
#                        |   |/ -10: the last ten
#                        |   |
#                        |   | /- oc: order by creation date
#                        |   | |
#                        |   | | 
#                        vvvvvvvv
newdevices=(/dev/block/*(Ncm-10oc))
counter=1
now=$(date +%s)
for dev in $newdevices; do
  creation=$(stat -c %W "${dev}")
  age=$((now-creation))
  age_minutes=$(( age/60 ))
  age_second=$(( age%60 ))
  printf '%d) %s (%d:%d)\n' $counter "$(basename "$(readlink -f "${dev}")")" $age_minutes $age_seconds
  counter=$((counter+1))
done
printf 'q) quit\nwhat? '

read choice
printf 'chose %d\n' "$choice"
[[ "$choice" = q ]] && exit
if ! [[ "$choice" =~ '^[0-9]+$' ]]; then
  printf 'Invalid number; quitting without action'
  exit 1
fi

choice=$(( choice )) #convert to integer
if [[ $choice -gt ${#newdevices} ]]; then
  printf 'choice %d larger than new devices (%d). Aborting.\n' $choice ${#newdevices}
  exit 2
fi

device="${newdevices[${choice}]}"
printf "Requesting to mount %s…\n" "${device}"
udisksctl mount -b "$(readlink -f "${device}")"

    复制并粘贴到文本文件中，将其保存为“可插入文件”，chmod 755 /path/to/pluggables使其可执行。然后以 身份运行/path/to/pluggables。

    • 3

相关问题