主页 / unix / 问题 / 778285
Accepted
matan h
Asked: 2024-06-13 20:17:44 +0800 CST

如何在 fish shell 中为 `history` 函数添加别名

  • 772

我正在尝试将鱼history寻呼机设置为bat -l fish用于语法突出显示。（即仅为命令设置PAGER环境变量）。bat -l fishhistory

我试过：

# 1:
alias history "PAGER='bat -l fish' history" 
# results in "The function “history” calls itself immediately, which would result in an infinite loop"

# 2:
alias history "PAGER='bat -l fish' \history"
# results in the same.

# 3:
alias _old_history history
alias history "PAGER='bat -l fish' _old_history"
# results in (line 1): The call stack limit has been exceeded

我知道abbr在这种情况下这是可行的，但这会改变我的history命令，这不是我想要的。

environment-variables

2 个回答

  1. Best Answer

    这里发生了两件事：

    1. fishalias实际上创建了一个函数。
    2. fish 已经带有默认历史记录功能。

    所以当你写

    alias history "PAGER='bat -l fish' history"

    你实际上拥有的是递归函数

    function history
  PAGER='bat -l fish' history $argv 
end

    一些解决方案：

    1. 使用不同的名称作为别名

      alias hist 'PAGER="bat -l fish" history'

    2. 不要alias _old_history hist，而是复制它

      functions --copy history _old_history
alias history 'PAGER="bat -l fish" _old_history'

    3. 如果你不想保留 fish 函数，可以在你自己的函数中调用内置的history 命令

      function history
  builtin history $argv | bat -l fish
end

    为什么内置历史记录不支持分页器？

    我认为鱼的设计者并不认为这是历史功能的核心部分。我认为他们将面向用户的内容放在用户可以覆盖的函数中。

    以下是默认历史记录功能的相关代码片段：

            case search # search the interactive command history
            test -z "$search_mode"
            and set search_mode --contains

            if isatty stdout
                set -l pager (__fish_anypager)
                and isatty stdout
                or set pager cat

                # If the user hasn't preconfigured less with the $LESS environment variable,
                # we do so to have it behave like cat if output fits on one screen.
                if not set -qx LESS
                    set -x LESS --quit-if-one-screen
                    # Also set --no-init for less < v530, see #8157.
                    if type -q less; and test (less --version | string match -r 'less (\d+)')[2] -lt 530 2>/dev/null
                        set -x LESS $LESS --no-init
                    end
                end
                not set -qx LV # ask the pager lv not to strip colors
                and set -x LV -c

                builtin history search $search_mode $show_time $max_count $_flag_case_sensitive $_flag_reverse $_flag_null -- $argv | $pager
            else
                builtin history search $search_mode $show_time $max_count $_flag_case_sensitive $_flag_reverse $_flag_null -- $argv
            end
    • 5

  2. 我成功functions -c复制了内置history函数。结果发现alias只是创建了一个history调用自身的函数，而functions -c完全复制了该函数。

    functions -c history _old_history
alias history "PAGER='bat -l fish' _old_history"

    （这是我最终在配置中使用的最终版本：

    functions -c history old_history
alias history 'PAGER="bat --file-name \"fish history\" -l fish" old_history'

    ）

    • 1

相关问题