主页 / unix / 问题 / 708627
Accepted
kohane15
Asked: 2022-07-05 21:21:15 +0800 CST

触发bindkey后如何取消zle功能？

  • 772

希望你做得很好。

我有以下内容.zshrc：

# 1. invoke zoxide to pick dir
# 2. open target dir in ranger
# 3. when exiting ranger, cd into last dir
zoxide_to_ranger () {
    eval 'ranger "$(zoxide query -i)" --choosedir=$HOME/.rangerdir < $TTY'
    LASTDIR=$(< ~/.rangerdir)
    cd "$LASTDIR" || exit

    # ensure `precmds` are run after `cd`
    local precmd
    for precmd in $precmd_functions; do
      $precmd
    done
    zle reset-prompt
}

zle -N zoxide_to_ranger
bindkey '^f' zoxide_to_ranger

正如内联评论中所建议的那样，它是一个方便的工具，当我触发时Ctrl-f，它会提示我一个 fzf 菜单，并且在选择后它将在该目录中打开 ranger。

问题是，当我想通过按 取消选择时Esc，它仍然会打开 ranger 并向我发送主目录，这不是我想要的。

所以我的问题是，如何在触发bindkey后取消这样的zle功能？

配置：

zsh 5.9 (x86_64-pc-linux-gnu)

操作系统：Manjaro Linux

非常感谢任何输入。谢谢：）

zsh zle

1 个回答

  1. Best Answer

    这eval条线正在做几件事。可能东西太多了。一种方法是分离zoxide调用，并检查它是否返回了一些东西。另一个需要是检查其中是否~/.rangerdir有目录（或其他东西），并在使用后清空该文件。这些新检查创建了函数必须清理和退出的多个点：

    function zoxide_to_ranger {
  local zz; zz=$(zoxide query -i)
  [[ -z $zz ]] && { zle reset-prompt; return }

  # not sure if the 'eval' is necessary; does ranger ever exit with
  # shell commands to be run?
  ranger $zz --choosedir=~/.rangerdir < $TTY

  local dd; dd=$(< ~/.rangerdir)
  [[ -z $dd ]] && { zle reset-prompt; return }
  :> ~/.rangerdir

  # this could be "local" unless you use it elsewhere
  LASTDIR=$dd
  cd $LASTDIR || { zle reset-prompt; return }

  local precmd; for precmd in $precmd_functions; $precmd
  zle reset-prompt
}
    • 1

相关问题