主页 / unix / 问题 / 701326
Accepted
raylight
Asked: 2022-05-04 15:04:07 +0800 CST

当 FS 已在使用时，如何使用 awk 拆分字符串？

  • 772

假设我有file.csv以下内容：

id;filename;device
1;118574934-20220503-17h44m20s101;
2;118574934-20220503-17h44m20s101;
3;118574934-20220503-17h44m20s101;DEVICE-0001-33
4;118574934-20220503-17h44m20s101;DEVICE-0001-33
5;118574934-20220503-17h44m20s101;DEVICE-0001-33
6;118574934-20220503-17h44m20s101;DEVICE-0001-33
7;118574934-20220503-17h44m20s101;DEVICE-0001-33

我创建了一个awk脚本，用于在设备名称出现在我的文件中时处理它，然后它完成执行。是功能性的script.awk，如下所示：

BEGIN {
    FS=";"
}
NR > 1 { fileName = $2 }
NR > 1 { if ( $3 != "" ) { device = $3; exit} }
END {
    if ( device == "" ) {
        line = "UNCONNECTED_"fileName".txt;UNCONNECTED"
    } else {
        line = device"_"fileName".txt;"device
    }
    print "filename;folder"
    print line
}

其执行后的输出awk -f script.awk file.csv为：

filename;folder
DEVICE-0001-33_118574934-20220503-17h44m20s101.txt;DEVICE-0001-33

问题是我想将字符串拆分DEVICE-0001-33为DEVICE-0001. 由于我已经使用FS过;并且我不能FS再次使用 as-来拆分我的device变量。我该如何处理awk？FS一旦已经被使用，如何使用特定字符拆分变量？

awk

1 个回答

  1. Best Answer

    对于您的情况，使用sub()似乎就足够了。$3您不想将, 也就是分配DEVICE-0001-33给您的变量，而是要使用它的子字符串。假设那-是里面的分隔符，你想删除最后一个字段。

    echo "DEVICE-0001-33" | awk '{sub(/-[^-]*$/,"",$1); print}'

DEVICE-0001

    我们使用-[^-]*$以获取最后一个分隔符和最后一个字段。不仅-.*$因为它很贪婪，而且会吃掉所有的田地，而且会吃掉第一个。替换是空字符串""。并将结果写入该字段。所以你可以device = $3用

    sub(/-[^-]*$/,"",$3); device = $3

    您问题标题的一般答案是使用该split()功能。它使您能够使用不同于FS. 这个例子描述了它在做什么：

    echo "DEVICE-0001-33" | awk -v s='-' '{
    n=split($1,arr,s)
    print "number of fields: " n
    print "separator: " s
    for (i=1;i<=n;i++) print "field: " i " value: " arr[i]
}'

number of fields: 3
separator: -
field: 1 value: DEVICE
field: 2 value: 0001
field: 3 value: 33

    你可以在这个字符串上做 awk 可以为一行做的事情。

    • 6

相关问题