在单个命令中使用两个分隔符从 awk 获取结果

所有你需要的是：

awk '/received/{print $4}'

例如，cat file用于获得与awk您的问题相同的输入：

$ cat file
PING 8.8.8.8 (8.8.8.8) 56(84) bytes of data.
64 bytes from 8.8.8.8: icmp_seq=1 ttl=128 time=8.04 ms
64 bytes from 8.8.8.8: icmp_seq=2 ttl=128 time=7.47 ms
64 bytes from 8.8.8.8: icmp_seq=3 ttl=128 time=7.72 ms
64 bytes from 8.8.8.8: icmp_seq=4 ttl=128 time=7.50 ms

--- 8.8.8.8 ping statistics ---
4 packets transmitted, 4 received, 0% packet loss, time 3007ms
rtt min/avg/max/mdev = 7.473/7.683/8.037/0.225 ms

$ cat file | awk '/received/{print $4}'
4

显然只是替换cat file为ping -c 4 8.8.8.8您的真实测试。

回应下面的 OP 评论，询问它在哪一行匹配：

$ awk '/received/' file
4 packets transmitted, 4 received, 0% packet loss, time 3007ms

以及为什么要打印第 4 个字段：

$ awk '/received/{for (i=1; i<=NF; i++) print i, "<" $i ">"}' file
1 <4>
2 <packets>
3 <transmitted,>
4 <4>
5 <received,>
6 <0%>
7 <packet>
8 <loss,>
9 <time>
10 <3007ms>

您已经得到了一些很好的 awk 答案，所以这里有一些替代方案。

1. GNUgrep

   $ ping -c 4 8.8.8.8 | grep -oP '\d+(?= received,)'
   4
   

2. Perl

   $ ping -c 4 8.8.8.8 | perl -lne 'print $1 if /(\d+) received,/'
   4
   

3. sed

   $ ping -c 4 8.8.8.8 | sed -En 's/.*, ([0-9]+) received,.*/\1/p'
   4
   

还有另一种方法可以做到这一点awk（类似于对其中一个答案的评论）

awk -F, '/received/ {print int($2)}'

函数int()将在第一个数字之后“丢弃”非数字信息

字段分隔符可以是正则表达式，因此您可以在 awk 中设置多个字段分隔符，[ ]例如：

awk -F '[, ]' '/received/ {print $5}'

但是在这种情况下，我可能会删除收到的单词：

 awk -F, '/received/ {sub(/received/, "", $2); print $2}'

awk sub() 函数sub(regexp, replacement [, target])将找到由正则表达式表示的模式，将其替换为replacement，并且可以选择将其缩小到目标列。

 ping -c4 <ipadress>|awk '/received/{for(i=1;i<=NF;i++){if($i ~ /received/){print $(i-1)}}}'

输出

4

这里的所有答案都很好地解决了 OP 的特定要求。

但是，它们都没有解决在除主 AWK 循环使用的“主”分隔符之外的分隔符上拆分字段的一般问题。

答案是使用我所知道的所有 AWK 版本中都可用的split()函数，包括One True AWK和POSIX 规范：

/received/ {
  split($2, recv, " "); print(recv[1])
}

这在标准输出上发出4：

awk -F ',' '
/received/ {
  split($2, recv, " "); print(recv[1])
}
' <<\EOD
PING 8.8.8.8 (8.8.8.8) 56(84) bytes of data.
64 bytes from 8.8.8.8: icmp_seq=1 ttl=128 time=8.04 ms
64 bytes from 8.8.8.8: icmp_seq=2 ttl=128 time=7.47 ms
64 bytes from 8.8.8.8: icmp_seq=3 ttl=128 time=7.72 ms
64 bytes from 8.8.8.8: icmp_seq=4 ttl=128 time=7.50 ms

--- 8.8.8.8 ping statistics ---
4 packets transmitted, 4 received, 0% packet loss, time 3007ms
rtt min/avg/max/mdev = 7.473/7.683/8.037/0.225 ms
EOD

Notesplit()与顶级记录拆分具有相同的语义FS。也就是说，它的行为应该与第二个分隔符完全相同。POSIX 规范暗示了这一点（但未明确说明），并在 GNU AWK 手册页中明确说明。这样做的主要效果是（如FS）如果分隔符模式是" "，则前导和尾随空格被剥离，连续的空白字符被视为单个空格。

bash 命令行：

recv=( $(ping -c 4 8.8.8.8 | grep received) ); echo ${recv[3]}

将“ping”的结果通过管道传输到“grep”作为数组“recv”；显示数组的第三个元素。

输出：

4

或者以最 awk 的方式进行操作，而无需实际计算字段：

mawk NF RS='^.+tted,[ \t]*|[ \t]*recei.+$' testfile4.txt

4

如果您使用 gawk 的快速打印功能，您可以看到 RT 匹配它的整个尾部：

RT: " received, 0% packet loss, time 3007ms\nrtt min/avg/max/mdev = 7.473/7.683/8.037/0.225 ms\n"