主页 / unix / 问题 / 692655
Accepted
Bianca
Asked: 2022-03-03 02:56:00 +0800 CST

从文件中选择相关数据（每列和每行）

  • 772

我有 file1 看起来像这样：

0 0
0 1
0 8
ST1 2 3
5 2
2 2
ST3 4 3
4 2
5 5
ST5 1 9
1 5
7 8

所需的输出文件：

ST1 6 5 2
ST3 12 4 5
ST5 9 1 7

如何解决这个问题？我想用awk。我不知道如何编写算法，以便我可以处理这些行以使其看起来像所需的输出。

这个想法是我想找到模式（ST）并从那个点开始处理。

输出文件方案：ST*，column2 乘以我们有“ST”的行的第 3 列，“ST”下方的行的第 1 列，但直到下一个“ST”出现。

我也不想在第一个 ST* 之前处理任何内容。

awk text-processing

4 个回答

  1. Best Answer

    与任何awk：

    $ awk '/^ST/{c=1} c{ printf "%s", (c++==1? ors $1 OFS $2*$3: OFS $1); ors=ORS } 
  END{ print "" }' infile
ST1 6 5 2
ST3 12 4 5
ST5 9 1 7
    • 3

  2. 假设每行有 2 个数字，您可以将记录分隔符 ( RS) 设置为“ ST ”：

    awk '
  BEGIN{RS="ST"}
  NR>1 {print RS $1, $2*$3, $4, $6}
' file

    输出：

    ST1 6 5 2
ST3 12 4 5
ST5 9 1 7

    注意：需要 GNU awk。

    • 1

  3. 处理此 pbm 的一种方法是

    awk -v ORS= '
($1 ~ /^ST[0-9]/) && (NF > 2) {
  if (f++) print RS
  print $1, $2*$3
  next
}
f {print "", $1}
END {print RS}
' file

    输出：

    ST1 6 5 2
ST3 12 4 5
ST5 9 1 7
    • 0

  4. 使用用于多字符 RS 和 RT 的 GNU awk 并假设每条记录始终有 3 行，如示例输入中所示：

    $ awk -v RS='ST([^\n]+\n){3}' '{$0=RT; print $1, $2*$3, $4, $6}' file
ST1 6 5 2
ST3 12 4 5
ST5 9 1 7
    • 0

相关问题