主页 / unix / 问题 / 691258
Accepted
Alexander Mills
Asked: 2022-02-19 11:21:04 +0800 CST

bash/zsh 挂钩 - 仅在未找到匹配文件时才添加到 PATH

  • 772

我正在寻找一个 bash/zsh钩子，当找不到命令时调用它。

假设我运行一些任意可执行文件：

xyz foo --bar
  1. 说 bash/zsh 找不到可执行文件。
  2. 有没有办法处理“未找到”，然后将一些库动态加载到 PATH 中？

像这样的东西：

function xyz {
  if ! test -f xyz; then
     load_libs xyz
  fi
  command -v xyz;
}

类似这个函数的东西，但它适用于未知的可执行文件。

所以一般来说它看起来像：

function on_not_found {
  if ! test -f "$1"; then
     load_libs "$1"
  fi
  command -v "$@";
}
bash shell

1 个回答

  1. Best Answer

    两者都zsh具有bash挂钩函数，您可以定义这些函数来处理找不到命令的情况。它被称为command_not_found_handleinbash和command_not_found_handlerin zsh（受bash's 启发，但错字/误称已修复）。

    但是请注意，它们在子进程中运行（更不用说子shell 可能找不到该命令），因此无法更改您的shell 环境。

    你可以这样做：

    zsh

    command_not_found_handler() {
  {
    if (( ! IN_CNFH++)) && load_lib "$1"; then
      "$@"
    else
      print -ru2 -- "$functrace[1]: command not found: $1"
      return 127
    fi
  } always {
    (( IN_CNFH-- ))
  }
}

    IN_CNFH如果命令成功后仍然找不到，避免无限递归的部分load_lib。

    如果您已经有一个command_not_found_handler（某些系统在其 zsh 默认配置中提供了一个，以在找不到命令时建议要安装的软件包的名称），您可以在它之前插入类似的内容：

    functions[command_not_found_handler]='
  {
    if (( ! IN_CNFH++)) && load_lib "$1"; then
      "$@"
      return
    fi
  } always {
    (( IN_CNFH-- ))
  }
  '$functions[command_not_found_handler]

    重击

    bash 中的等效项如下所示：

    command_not_found_handle() {
  local ret
  if (( ! IN_CNFH++)) && load_lib "$1"; then
    "$@"
    ret=$?
  else
    printf >&2 '%s\n' "$BASH_ARGV0: $1: command not found: $1"
    ret=127
  fi
  (( IN_CNFH-- ))
  return "$ret"
}

    或者增量变体，以防已经存在command_not_found_handle：

    eval 'command_not_found_handle() {
  local ret
  if (( ! IN_CNFH++)) && load_lib "$1"; then
    "$@"
    ret=$?
    (( IN_CNFH-- ))
    return "$ret"
  fi
  (( IN_CNFH-- ))
  '"$(typeset -f command_not_found_handle | tail -n +2)"'
}'
    • 1

相关问题