主页 / unix / 问题 / 680502
Accepted
Nainita
Asked: 2021-12-08 05:35:16 +0800 CST

如何用上一行的数据替换没有数据的行

  • 772

输入

Time      Value  Flag
06:15:10  49.95  Actual
00:00:00  0.00  NoValue
06:22:50  49.94  Actual
06:23:00  49.93  Actual
06:23:10  49.93  Actual
06:23:20  49.93  Actual
06:23:30  49.93  Actual
06:24:40  49.92  Actual
00:00:00  0.00  NoValue

我必须替换包含“NoValue”的行。时间将替换为上次记录的时间，增量为 10 秒（10 秒） 值将替换为上次记录的时间 标志将替换为实际

我的结果将显示为，

Time      Value  Flag
06:15:10  49.95  Actual
06:15:20  49.95  Actual
06:22:50  49.94  Actual
06:23:00  49.93  Actual
06:23:10  49.93  Actual
06:23:20  49.93  Actual
06:23:30  49.93  Actual
06:24:40  49.92  Actual
06:24:50  49.92  Actual
text-processing scripting

3 个回答

  1. Best Answer
    awk -F'[: ]+' -v addSec=10 '
 NR>1 && /Actual/{
     sec=(($1*3600)+($2*60)+$3) +addSec;
     prevTime=sprintf("%02d:%02d:%02d", sec/3600, sec%3600/60, sec%60) OFS $4 OFS $5;
 }
 /NoValue/{ $0=prevTime }1
' infile
    • 3

  2. 尝试这个：

    猫小说 | tr -s " " | awk -F"[: ]" -f val.awk

    在哪里：

    cat noval 
06:15:10  49.95  Actual
00:00:00  0.00  
06:22:50  49.94  Actual
06:23:00  49.93  Actual
06:23:10  49.93  Actual
06:23:20  49.93  Actual
06:23:30  49.93  Actual
06:24:40  49.92  Actual
00:00:00  0.00

    和

    cat val.awk
{
    if($5=="") {
        print g
                   }
        else {
               print $0
           $3=$3+10
               if ($3>59){
        $3=$3-60
        $2=$2+1
               }
               if ($2>59){
                  $2=$2-60
                  $1=$1+1
               }
if(length($1)<2) {$1="0"$1}
if(length($2)<2) {$2="0"$2}
if(length($3)<2) {$3="0"$3}
               g=$1":"$2":"$3" "$4" "$5
              }
}

    结果是：

    06:15:10 49.95 Actual
06:15:20 49.95 Actual
06:22:50 49.94 Actual
06:23:00 49.93 Actual
06:23:10 49.93 Actual
06:23:20 49.93 Actual
06:23:30 49.93 Actual
06:24:40 49.92 Actual
06:24:50 49.92 Actual

    注意：使用 awk 我们沿着字符冒号 (:) 和空格分解每一行。这样我们就可以访问时间戳的三个组件（第 1、2、3 列），以便可能添加 10。我们使用 tr 将多个空格压缩为一个。awk 中的 F 标志设置为沿冒号和/或空间分解行以进行操作。

    • 1

  3. 在不知道时间戳适用的日期和时区以及使用理解日期和时间的实用程序（即不仅仅是简单的数学）的情况下，您无法通过在现有时间上增加 10 秒来确定新时间，因为新时间是给定时间增加 10 秒受夏令时和闰秒影响。

    假设您的输入时间戳的开始日期是今天，然后使用 GNU awk 作为时间函数（它处理 DST，但与处理 POSIX 纪元时间的所有工具一样，不处理闰秒，所以希望您不关心那个):

    $ cat tst.awk
BEGIN {
    OFS = "  "
    prevDate = (date=="" ? strftime("%Y %m %d") : date)
}
NR == 1 {
    print
    next
}
$3 == "NoValue" {
    prevTime = gensub(/:/," ","g",prevLine[1])
    prevSecs = mktime(prevDate " " prevTime)
    currSecs = prevSecs + 10
    prevDate = strftime("%Y %m %d",currSecs)
    $1 = strftime("%T",currSecs)
    $2 = prevLine[2]
    $3 = prevLine[3]
}
{
    print
    split($0,prevLine)
}


    $ awk -f tst.awk file
Time      Value  Flag
06:15:10  49.95  Actual
06:15:20  49.95  Actual
06:22:50  49.94  Actual
06:23:00  49.93  Actual
06:23:10  49.93  Actual
06:23:20  49.93  Actual
06:23:30  49.93  Actual
06:24:40  49.92  Actual
06:24:50  49.92  Actual

    如果您希望将时间计算应用于您的计算机设置的其他时区，请TZ在执行上述操作之前适当设置 shell 变量，或在调用mktime()and时设置 UTC 标志strftime()，请参阅https://www。 gnu.org/software/gawk/manual/gawk.html#Time-Functions。

    如果您想使用与今天不同的开始日期，请调用脚本以awk -v date='2021 10 03' -f tst.awk file提供您喜欢的任何日期YYYY MM DD格式。

    以上假设时间戳将始终填充在您输入的第二行，因为您没有说明如何处理它。

    请注意，正如@PhilipCouling 在评论mktime()（或任何其他库）中指出的那样，仅给出一个日期和时间就不能可靠地返回自 DST 结束时转换间隔期间具有 DST 的时区的纪元以来的秒数（DST 开始时很好）。他们提供的例子是：

    在英国，日期/时间 30-Oct-2022 01:30:00am 将发生两次。那是因为当时钟到达凌晨 2 点时，DST 将结束，时钟会跳回一个小时到凌晨 1 点。所以 1:30 在 DST 结束之前和 DST 结束之后发生一次。该文件不包含有关它描述的这两个中的哪一个的任何信息。该文件不会告诉您 DST 是否已经结束。

    • -1

相关问题