主页 / unix / 问题 / 677446
Accepted
math
Asked: 2021-11-15 01:05:19 +0800 CST

如何通过 unix 命令将带有键值对的文本文件转换为有序输出

  • 772

我有一个文本文件，其中包含不同变量的可能值范围

1. life:        short,long,na.
2. weather_f:   cloudy,rainy,sunny,foggy,cold,warm,mild,
                    humid,na.
3. sea_temp:    warm,mild,cold,na.

我想得到一个看起来像这样的输出文件

short,long,na
cloudy,rainy,sunny,foggy,cold,warm,mild,humid,na
warm,mild,cold,na

我尝试使用sed它，但新行weather_f让我很难过。我怎样才能达到预期的输出？

shell

1 个回答

  1. Best Answer

    当一行以逗号结尾时，立即将下一行附加到缓冲区。这是通过sed使用表达式完成的

    /,$/N

    该N命令将下一行附加到缓冲区中的文本，并在两者之间使用换行符作为分隔符。

    要允许多个这样的连续行，请循环回到循环的开头以检查缓冲区末尾是否有逗号。

    :again
/,$/ {
    N

    # branch to the "again" label at the top
    b again
}

    在此之后，我们不再需要附加到缓冲区中的行，因此我们可以开始修剪行并按照我们想要的方式排列它。这包括删除直到第一个:字符的所有内容，删除所有类似空格的字符（包括由 插入的换行符N），并在最后切掉点。

    s/[^:]*://
s/[[:space:]]//g
s/\.$//

    整个编辑脚本将是

    :again
/,$/ {
    N
    b again
}
s/[^:]*://
s/[[:space:]]//g
s/\.$//

    这可以使用文件（此处为script）中的脚本执行，例如

    sed -f script file

    或者，如果您想在命令行上键入脚本，

    sed -e :again \
    -e '/,$/ { N; b again; }' \
    -e 's/[^:]*://' \
    -e 's/[[:space:]]//g' \
    -e 's/\.$//' file

    鉴于您问题中的数据，这将输出

    short,long,na
cloudy,rainy,sunny,foggy,cold,warm,mild,humid,na
warm,mild,cold,na

    一些sed实现可能需要b again是它自己的表达式：

    sed -e :again \
    -e '/,$/ { N' -e 'b again' -e '}' \
    -e 's/[^:]*://' \
    -e 's/[[:space:]]//g' \
    -e 's/\.$//' file
    • 5

相关问题