从公共数据文件创建单独的表格输出，并计算出一些总数

编辑：

Ed Mortons的回答更好，请使用它。

awk 'function print_entry(a,b,c,d) {
    k=split(c, ce, " ")
    split(d, dn, " ")
    for(i=1; i<=k; i++) {
        if(i%50==1) printf("\f%s\n%s\n%s\n%s\n",
            "PERSONS HAVING OUTSTANDING ADVANCE SALARY",
            "+==============================+",
            "|Sr.|   name   |Amount Rs.|Nos |",
            "+==============================+")
        printf("|%3s|%10s|%10.2f|%4d|\n",i,a,ce[i],dn[i])
    }
    print "================================"
    print "Total for",a,k,b
    print "================================"
    printf("\f")
}
BEGIN {FS="|"}
{
    if($1==name) {
        total+=$2
        entry=(entry " " $2)
        nos=(nos " " $3)
    }
    else {
        if(name) print_entry(name,total,entry,nos)
        name=$1
        total=$2
        entry=$2
        nos=$3
    }
}
END {if(name) print_entry(name,total,entry,nos)}' data.txt

主要逻辑：

• 收集与姓名相关的信息 ( $1)
  • total$2将每个条目相加
  • entry保留每个$2条目的列表
  • nos保留每个$3条目的列表
• 每次更改名称时，打印收集到的信息
  • 拆分$2条目列表，给出该k名称的条目数，$3列表也被拆分（它应该具有相同的条目数）
  • 从 1 ( i=1) 开始，打印每个条目
  • 如果i mod 50是1打印标题 - 这将每五十个条目打印一个新标题
  • 然后打印总数

• 该函数的使用print_entry使主要动作更清晰，更易于阅读，并且在END动作中再次使用它，因此将其定义为函数可以避免重复

$ cat tst.awk
BEGIN { FS="|" }
$1 != prev {
    if ( NR>1 ) {
        prtTail()
    }
    prtHead()
    srval = 0
    tot   = 0
    prev  = $1
}
{
    tot += $2
    printf "|%3s|%10s|%10.2f|%4d|\n", ++srval, $1, $2, $3
}
END { prtTail() }

function prtHead() {
    print "PERSONS HAVING OUTSTANDING ADVANCE SALARY"
    print "+==============================+"
    print "|Sr.|   name   |Amount Rs.|Nos |"
    print "+==============================+"
}

function prtTail() {
    print "================================"
    printf "Total for %s %d %d\n", prev, srval, tot
    print "================================"
    print ""
}

.

$ awk -f tst.awk file
PERSONS HAVING OUTSTANDING ADVANCE SALARY
+==============================+
|Sr.|   name   |Amount Rs.|Nos |
+==============================+
|  1|   Kalpesh|    100.00|   1|
|  2|   Kalpesh|    500.00|   1|
================================
Total for Kalpesh 2 600
================================

PERSONS HAVING OUTSTANDING ADVANCE SALARY
+==============================+
|Sr.|   name   |Amount Rs.|Nos |
+==============================+
|  1|    Ramesh|    500.00|   1|
|  2|    Ramesh|    500.00|   1|
|  3|    Ramesh|    500.00|   1|
================================
Total for Ramesh 3 1500
================================

PERSONS HAVING OUTSTANDING ADVANCE SALARY
+==============================+
|Sr.|   name   |Amount Rs.|Nos |
+==============================+
|  1|    Naresh|    500.00|   1|
================================
Total for Naresh 1 500
================================

PERSONS HAVING OUTSTANDING ADVANCE SALARY
+==============================+
|Sr.|   name   |Amount Rs.|Nos |
+==============================+
|  1|    Ganesh|    500.00|   1|
|  2|    Ganesh|    500.00|   1|
|  3|    Ganesh|    500.00|   1|
|  4|    Ganesh|    500.00|   1|
================================
Total for Ganesh 4 2000
================================