主页 / unix / 问题 / 557384
Accepted
user386465
Asked: 2019-12-16 10:02:44 +0800 CST

awk 部分字符串匹配

  • 772

所以我试图部分匹配一个字段中的字符串，然后将该字段与单独文件中的另一个字段一起使用，

输入示例 -

输入1.txt：

example/world
example/forever

输入2.txt

example123
example234

预期输出.txt：

example123/world
example234/world
example123/forever
example234/forever

所以基本上使用 AWK 将 input1.txt 分成 2 个字段，使用 -

awk -F"/"

这意味着第一行 $1 是example$2 是world

然后example通过部分匹配 input2.txt 中的 $1 来检查 input2.txt 是否包含，然后找到这些匹配项并将它们与 input1 的 $2 组合。

awk gawk

3 个回答

  1. Best Answer
    awk -v file2="input2.txt" -F'/' '{
  while ((getline line < file2) > 0){
    if (line ~ "^"$1) print line FS $2
  }
  close(file2)
}' input1.txt

    这基本上就是你所描述的。对于input1.txtfrom 的所有行中的每一行，都input2.txt被读取并与$1. 如果匹配，input2.txt则 ' 行将使用分隔符/和打印$2。

    • 1

  2. 这是部分字符串匹配的方法：

    $ cat tst.awk
BEGIN { FS=OFS="/" }
NR==FNR {
    strings[$1]
    next
}
{
    for (string in strings) {
        if ( index(string,$1) ) {
            print string, $2
        }
    }
}

$ awk -f tst.awk input2.txt input1.txt
example234/world
example123/world
example234/forever
example123/forever

    如果您只想在字符串开头进行匹配，则只需更改index(...)为index(...) == 1.

    • 0

  3. awk基于提供的示例文件的另一种解决方案：

    $ cat demo.awk
BEGIN { FS="/"; while ((getline < "input2.txt" ) > 0 ) { s[i++] = $0 } }

{ for (i in s)
    if (s[i] ~ "^"$1) { print s[i] FS $2 }
    # alternative tests
    # if (index(s[i], $1)) { print s[i] FS $2 }
    # if (index(s[i], $1) == 1) { print s[i] FS $2 }
}

    输出：

    $ awk -f demo.awk input1.txt
example123/world
example234/world
example123/forever
example234/forever
$
    • -1

相关问题