主页 / unix / 问题 / 555244
Accepted
Kodiologist
Asked: 2019-12-03 12:13:52 +0800 CST

Zsh 中的 Readline 样式括号突出显示

  • 772

有时我在 Zsh 中编写了一个长命令，或者更确切地说，一个 Zsh 命令以一个包含另一种语言（如 R 或 Perl）的代码的长字符串文字结尾，我忘记了我的括号、方括号或大括号。当您键入右括号时，Readline 变量blink-matching-paren会短暂闪烁相应的左括号。我怎样才能为 Zsh 获得类似的东西？更好的是等效于 Emacs 的show-paren-mode，只要文本光标位于括号上，它就会突出显示相应的匹配括号。

brackets荧光笔是在这个方向上的zsh-syntax-highlighting东西，但它在带引号的构造中不起作用，这是我真正需要它的地方（尽管令人困惑的是，如果括号被反斜杠转义，它仍然会突出显示）。

zsh syntax-highlighting

1 个回答

  1. Best Answer

    我认为没有zsh等效的内置机制，但是您应该能够使用自定义小部件来做到这一点，例如：

    zmodload zsh/zselect
showmatch() {
  emulate -L zsh
  set -o rematchpcre
  local -A pair=(
    ']' '['
    ')' '('
    '}' '{'
  )
  local MBEGIN

  zle .self-insert
  if [[ $LBUFFER =~ "(\\$pair[$KEYS](?:[^$KEYS$pair[$KEYS]]++|(?1))*\\$KEYS)\$" ]]; then
    local oldCURSOR=$CURSOR
    CURSOR=$MBEGIN-1
    zle -R
    zselect -t 50 -r 0 < /dev/tty
    CURSOR=$oldCURSOR
  fi
}
zle -N showmatch
bindkey ']' showmatch
bindkey ')' showmatch
bindkey '}' showmatch

    if您还可以通过将/的内部替换为以下内容来临时突出显示匹配括号之间的区域fi：

        local oldCURSOR=$CURSOR
    region_highlight+=("$((MBEGIN-1)) $CURSOR bg=yellow,fg=black,bold")
    CURSOR=$MBEGIN-1
    zle -R
    zselect -t 50 -r 0 < /dev/tty
    CURSOR=$oldCURSOR
    region_highlight[-1]=()

    （此处以黄底黑字突出显示）。

    show-paren-mode当光标碰到一端时，您还可以将其与匹配括号的类似突出显示结合起来，例如：

    zmodload zsh/zselect
SHOWMATCH_GR=fg=black,bg=yellow,bold

showmatch() {
  emulate -L zsh
  set -o rematchpcre
  local -A pair=(
    ']' '['
    ')' '('
    '}' '{'
  )
  local MBEGIN

  zle .self-insert
  if [[ $LBUFFER =~ "(\\$pair[$KEYS](?:[^$KEYS$pair[$KEYS]]++|(?1))*\\$KEYS)\$" ]]; then
    local oldCURSOR=$CURSOR
    local -a old_region_highlight=($region_highlight)
    region_highlight+=("$((MBEGIN-1)) $CURSOR $SHOWMATCH_GR")
    CURSOR=$MBEGIN-1
    zle -R
    zselect -t 50 -r 0 < /dev/tty
    CURSOR=$oldCURSOR
    region_highlight=($old_region_highlight)
  fi
}
zle -N showmatch
bindkey ']' showmatch
bindkey ')' showmatch
bindkey '}' showmatch

zle-line-pre-redraw() {
  emulate -L zsh
  set -o rematchpcre
  region_highlight=(${region_highlight:#* $SHOWMATCH_GR})
  local a=$BUFFER[CURSOR+1] b c MBEGIN o=0
  local -A pair=(
    ']' '['
    ')' '('
    '}' '{'
  )
  [[ -n "$RBUFFER" ]] &&
  case $a in
    ([[\({])
      b=${(k)pair[(re)$a]}
      [[ $RBUFFER =~ "^(\\$a(?:[^$b$a]++|(?1))*\\$b)" ]] && o=$CURSOR;;
    ([]\)}])
      b=$pair[$a]
      [[ $LBUFFER$a =~ "(\\$b(?:[^$a$b]++|(?1))*\\$a)\$" ]];;
    (*) return;;
  esac &&
    region_highlight+=("$((o+MBEGIN-1)) $((o+MEND)) $SHOWMATCH_GR")
}
zle -N zle-line-pre-redraw
    • 2

相关问题