主页 / unix / 问题 / 507768
Accepted
villapx
Asked: 2019-03-22 09:03:37 +0800 CST

awk 一次分配给多个变量

  • 772

我正在尝试从字符串中提取两个数值并将它们分配给使用的变量awk（gawk是我专门使用的）。我想将主要和次要版本号从 tmux 版本字符串中提取到awk变量中，例如：

  • 输入：tmux 2.8; maj == 2和min == 8
  • 输入：tmux 1.9a; maj == 1和min == 9
  • 输入：tmux 2.10; maj == 2和min == 10

假设我的输入来自tmux -V标准输入，我目前有以下内容：

tmux -V | awk '{
                  maj = +gensub(/([0-9]+)\..*/, "\\1", "g", $2);
                  min = +gensub(/.*\.([0-9]+).*/, "\\1", "g", $2);
                  # ...do something with maj and min...
               }'

这可行，但正如许多 tmux 用户所知，if-shell在.tmux.conf文件中使用（我希望在其中使用这些东西）很容易导致配置文件中的行很长，所以我想知道是否有办法将这两个变量结合起来分配到一个语句中以节省空间......或任何其他方式从输入中收集这两个变量并节省空间。

我在想类似的东西：

awk '{ maj, min = +gensub(/([0-9]+)\.([0-9]+).*/, "\\1 \\2", "g", $2); }'

...有点像 Python 中的，但特定的语法在awk. 还有什么可能的吗？

请注意，可读性并不是真正的问题，只是长度。

awk gawk

4 个回答

  1. 由于您使用的是 GNU awk，因此您可以使用 3-arg 形式match()来存储多个捕获组：

    awk '
    match($0, /([0-9]+)\.([0-9]+)/, m) {maj=m[1]; min=m[2]; print maj, min}
' <<END
tmux 2.8
tmux 1.9a
tmux 2.10
END

    2 8
1 9
2 10

    https://www.gnu.org/software/gawk/manual/html_node/String-Functions.html

    • 12
  2. Best Answer

    请注意，这gensub是一个gawk扩展，它不适用于任何其他awk实现。另请注意，+一元运算符不会在所有awk实现中强制进行数字转换，使用+ 0更便携。

    在这里你可以这样做：

    tmux -V | awk -F '[ .]' '{maj = $2+0; min = $3+0; print maj, min}'

    如果你不介意使用 GNUawk扩展，你也可以这样做：

    tmux -V | awk -v FPAT='[0-9]+' '{maj = $1; min = $2; print maj, min}'
    • 9

  3. 您可以将版本拆分为一个数组：

    awk '{ split($2, ver, /[.a-z]/) }'

    然后使用ver[1]代替maj，ver[2]而不是min。

    添加a-z到分隔符会删除版本号中的所有小写字母。（其他解决方案在这里更好，因为它们明确地提取数字。）

    • 5

  4. 另一个用户发布了这个答案，后来被删除了。我认为它很有用：

    使用该split()函数，将版本字符串拆分为一个数组ver，然后分别访问ver[1]和ver[2]而不是maj和min（或简单地将值存储在这些变量中）：

    tmux -V | awk '{ split($2, ver, /[.a-z]/); print ver[1], ver[2] }'

    这里的优点是它split()不是gawk扩展（尽管它的可选第四个参数seps是）。

    • 3

相关问题