主页 / unix / 问题 / 507656
Accepted
Inian
Asked: 2019-03-22 01:00:12 +0800 CST

命令失败时未设置 GNU awk ERRNO

  • 772

getline()我正在尝试使用GNU 的函数运行一些命令awk并打印errno返回的错误号 ( ) 值。但是对于不存在目录/文件的简单故障情况，该变量似乎没有被填充。

awk 'BEGIN {
        cmd = "ls -lrth /non/existing/path"
        while ( ( cmd | getline result ) > 0 ) {
            print result
        }
        close(cmd); print ENVIRON["ERRNO"]
}'

当上述从 中取出错误字符串时ls，该print语句不会产生有效的错误号。我也尝试从手册页中使用PROCINFO["errno"]，PROCINFO["ERRNO"]但没有奏效。我还尝试在关闭文件描述符之前打印它也不起作用。ENOENT在这种情况下期望是错误的吗？

awk gawk

2 个回答

  1. Best Answer

    您无法使用getline. 在您的命令中，输出来自ls，而不是print result。

    在 formcmd | getline result中cmd运行，然后将其输出通过管道传输到getline. 1如果有输出，0如果 EOF，-1失败时返回。问题是失败来自运行getline本身，而不是cmd. 例子：

    awk 'BEGIN {
while ( ( getline result < "/etc/shadow") > 0 ) {
            print result
        }
        print "XXX: ", ERRNO
}'
XXX:  Permission denied

    您会看到/etc/shadow无法读取，因此getline无法运行并在ERRNO变量中报告错误。

    请注意，cmd如果不是 posix 模式，GNU awk 将返回状态，因此您可以执行以下操作：

    awk 'BEGIN {
    cmd = "ls -lrth /non/existing/path"
    while ( ( cmd | getline result ) > 0 ) {
        print result
    }
    status=close(cmd);
    if (status != 0) {
        code=and(rshift(status, 8),0xFF)
        printf("Exit status: %d, exit code: %d\n", status, code)
    }
}'
ls: cannot access '/non/existing/path': No such file or directory
Exit status: 512, exit code: 2

    在 POSIX 模式下，您不会获得退出状态：

    POSXILY_CORRECT=1 awk 'BEGIN {
    cmd = "ls -lrth /non/existing/path"
    while ( ( cmd | getline result ) > 0 ) {
        print result
    }
    status=close(cmd);
    if (status != 0) {
        code=and(rshift(status, 8),0xFF)
        printf("Exit status: %d, exit code: %d\n", status, code)
    }
}'
ls: cannot access '/non/existing/path': No such file or directory
    • 6

  2. 如果 getline 或 close 失败， ERRNO 将仅由 gawk 设置（仅限GNU awk ），但它成功读取 ls 的（空！）输出。该输出是空的，因为 ls 在标准错误通道上给出了错误消息（“ls: cannot access ...”），没有向标准输出写入任何内容，并且存在错误代码。

    使用 GNU awk，您可以像这样获得命令的退出状态：

    exitstatus=close(cmd)
if (exitstatus) {
    # do something
}

    如果您需要命令的错误消息，则必须将其标准错误通道重定向到某个文件，并阅读：

    awk 'BEGIN {
    cmd = "ls -lrth /non/existing/path 2>standard-error.txt"
    while ( ( cmd | getline result ) > 0 ) {
        print result
    }
    es=close(cmd);
    if (es) {
        getline errstring < "standard-error.txt"
        print "exitstatus "es" error message "errstring;
    }
}'
    • 4

相关问题