主页 / unix / 问题 / 470262
Accepted
Siva
Asked: 2018-09-21 04:15:02 +0800 CST

按第一列合并多个文件

  • 772

我在一个目录中有 50 多个具有不同名称的文件。例如：

文件1：

Type,A,
RR,1,
CD,2,

文件2：

Type,B,
CD,2,
FG,3,

文件3：

Type,C,
RR,5,
FG,8,
QR,9,

期望的输出

Type,A,B,C,
CD,2,2,,
FG,,3,8,
QR,,,9,
RR,1,,5

我试过但没有运气......有什么建议吗join？paste

rhel awk

2 个回答

  1. Best Answer

    这是一些相当棘手的 GNU awk。数组中的数组gawk需要GNU awk ( )

    gawk -F, '
    NR  == 1 {n=1; header[n] = $1}
    FNR == 1 {n++; header[n] = $2; next}

    !($1 in data) {data[$1][1] = $1}
    {data[$1][n] = $2}

    # from https://www.gnu.org/software/gawk/manual/html_node/Join-Function.html
    function join(array, start, end, sep,    result, i)
    {
        if (sep == "")
            sep = " "
        else if (sep == SUBSEP) # magic value
            sep = ""
        result = array[start]
        for (i = start + 1; i <= end; i++)
            result = result sep array[i]
        return result
    }

    END {
        print join(header, 1, n, FS)
        PROCINFO["sorted_in"] = "@ind_str_asc"   # for sorted output
        for (type in data)
            print join(data[type], 1, n, FS)
    }
' file{1,2,3}

    Type,A,B,C
CD,2,2,
FG,,3,8
QR,,,9
RR,1,,5

    我假设每个文件都有 2 列，所以它不是完全通用的。

    不依赖 GNU awk 的版本（用 mawk 测试）

    mawk -F, '
    NR  == 1 {n=1; header[n] = $1}
    FNR == 1 {n++; header[n] = $2; next}
    {key[$1]; data[$1,n] = $2}
    END {
        for (i=1; i<=n; i++)
            printf "%s%s", header[i], (i==n ? ORS : FS)
        for (type in key) {
            printf "%s%s", type, FS
            for (i=2; i<=n; i++)
                printf "%s%s", data[type,i], (i==n ? ORS : FS)
        }
    }
' file{1,2,3}
    • 0

  2. 即使没有真正的多维数组，这也不是特别难做到：

    /Type/ { type=$2; types[$2] = 1 }
!/Type/ { data[type,$1] = $2; keys[$1] = 1 }
END {
    m = asorti(types)
    value = "Type"
    for (i = 1; i <= m; i++) {
        value = value "," types[i];
    }
    print value;
    n = asorti(keys)
    for (i = 1; i <= n; i++) {
        value=keys[i]
        for (k = 1; k <= m; k++) {
            value = value "," data[types[k],keys[i]]
        }
        print value;
    }
}

    但是，您仍然需要 GNUawk来执行排序功能。

    • 0

相关问题