主页 / unix / 问题 / 468002
Accepted
don_crissti
Asked: 2018-09-11 03:10:23 +0800 CST

从模式空间中删除第一行的便携式方法（当存在多行时）

  • 772

从模式空间中删除第一行1的便携式方法是什么？
我gnu sed能做到

s/[^\n]*\n//

但据我所知，这（\n在括号[]表达式中使用）是不可移植的。

实际示例：在这里，sed通过可移植代码打印文件的最后一部分，包括分隔符。我想从模式空间中删除第一行，以便排除分隔符并以可移植的方式执行此操作。很gnu sed简单：

sed 'H;/===/h;$!d;//d;x;s/[^\n]*\n//' infile

1：显然这应该在不重新启动命令循环的情况下完成......

sed

3 个回答

  1. 我没有合适的 sed 可供尝试，但您始终可以进行内部循环测试和删除字符，直到您到达换行符：

    sed 'H
/===/h
$!d
//d
x
{
   :rpt
   s/^\n//
   t done
   s/.//
   t rpt
}
:done
'

    第二个测试分支 ,t rpt需要是 at而不是 ab以便重置表示s自上次读取以来 an 已成功的内部标志。您不需要{}，它们只是为了更好地显示循环。

    • 2
  2. Best Answer

    便携地做这种事情的一种方法如下：

    sed -e '
   # ... assuming prev sed cmds made pattern space carry newline(s)
   y/\n_/_\n/     ;# exchange newlines with an underscore
   s/^[^_]*_//    ;# remove up till the first underscore, ummm newline
   y/\n_/_\n/     ;# revert the transformation
'
    • 2

  3. 愚蠢，但工作：

    sed 'h;G;s/\n/&&/;s/^\(.*\)\n\(.*\)\n\1\2$/\2/'

    那是什么？您将整个内容加倍，然后用两个换行符替换第一个换行符。所以你有两次相同的内容，第一行之后有一个额外的换行符。通过反向引用，您现在可以识别不同的部分。

    如果您不想使用保持缓冲区：

    sed 's/.*/&&/;s/\n/&&/;s/^\(.*\)\n\(.*\)\1\2$/\2/'

    不，我不喜欢那样。如果有办法避免它，请避免它。

    • 1

相关问题