主页 / unix / 问题 / 447254
Accepted
Siva
Asked: 2018-06-01 23:10:26 +0800 CST

AWK - 打印最后一列以及空值

  • 772

$NF如果我们不知道最后一列号，我们可以打印文件中每一行的最后一列。

但我面临的困难是最后一列有一个空值。

例如，解析who命令

$ who
root     tty1         2018-01-25 09:36
root     pts/0        2018-05-30 07:39 (192.168.1.134)
root     pts/1        2018-05-28 23:12 (192.168.1.134)
root     pts/2        2018-06-01 10:01 (192.168.1.188)

得到结果：

$ who | awk '{print $NF}'
09:36
(192.168.1.134)
(192.168.1.134)
(192.168.1.188)

预期结果

(192.168.1.134)
(192.168.1.134)
(192.168.1.188)

让我知道在单行中获得预期结果的可能性。

编辑 1：上述情况只是一个例子。我不喜欢更改分隔符来达到结果。

编辑 2：字段少于最大值的行中没有任何内容（输出的空行）

linux shell-script

4 个回答

  1. Best Answer

    要仅输出具有最大列数的行的最后一列，您可以执行以下操作：

    who | awk '
  NF > max  {max = NF; output = ""}
  NF == max {output = output $NF ORS}
  END       {printf "%s", output}'

    要为每一行输入输出一行，但对于没有最大列数的行为空：

    who | awk '
  NF > max {max = NF}
  {n[NR] = NF}
  NF == max {last[NR] = $NF}
  END {for (i = 1; i <= NR; i++) print n[i] == max ? last[i] : ""}'
    • 5

  2. 如果您只希望拥有最多字段的行中的最后一个字段，则需要两次读取数据：一次找出最多的字段数，另一次打印字段。只读一次并不能解决问题：任何一行都可以有比以前更多的字段，而且没有办法知道。

    使用awk（注意文件名给出了两次）：

    awk -vfields=0 'FNR==NR {if (NF > fields) fields=NF; next} 
     NF >= fields { print $NF } NF < fields {print ""}' file file

    如果file包含

    foo bar
one two three four
1 2 3
a b c d

    这将打印第四个字段，或者对于没有它的行为空：

    四

d

    这当然不适用于管道，您必须使用临时文件。

    另一种解决方案可以缓存要打印的字段，直到出现包含更多字段的行，如Stéphane 的回答。

    • 3

  3. 检查第 5 个字段是否匹配\(.*\)，如果匹配则打印。

    who | awk '$5 ~ /\(.*\)/{print $5}'

    如果您只对ip地址感兴趣，请更改正则表达式：

    who |  awk '$5 ~ /\((25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.(25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\)/{print $5}'
    • 1

  4. 如果您只想在此列可用的情况下获取最后一列，请使用您不想要的行只有四列的事实：

    who | awk 'NF > 4 { print $NF }'

    或者，为了获得类似的数据，

    w -hi | awk '{ print $3 }'
    • 0

相关问题