主页 / unix / 问题 / 442976
Accepted
acroniks
Asked: 2018-05-11 02:37:55 +0800 CST

sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;' 如何 用于打印段落[重复]

  • 772

谁能解释一下下面的 sed 命令如何打印段落？

命令：

sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;' file

如果可能的话，任何人都可以通过将这个命令分成几部分来解释，这样我就可以完全理解如何根据不同的条件修改命令。

regular-expression sed

1 个回答

  1. Best Answer

    命令

    sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;' file

    打印包含字符串的段落AAA。

    sed这使用以下sed脚本调用：

    /./{
    H
    $!d
}
x
/AAA/!d

    注释版本：

    /./{        # When hitting a line that contains at least one character...
    H;      # Append the line to the "hold space".
    $!d;    # If it's not the last line, delete it.
}
x;          # Swap the hold space and the pattern space.
/AAA/!d;    # Delete the pattern space if it does not contain the string "AAA"
            # (implicit print)

    因此，简而言之，它在“保持空间”（中的通用缓冲区sed）中逐行收集，当它找到空行（/./模式不匹配）时，它会确定存储的行集合是否包含字符串AAA如果是，则打印它。

    这也在此处的答案中进行了描述：GREP / SED 或 AWK：在模式匹配的文件中打印整个段落

    给定文件

    this is
a paragraph

this is
another one

this paragraph
contains the string
AAA

    它将输出最后一段（带有前导空行）。

    要摆脱每个输出段落之前的空行（如果这是您想要的），请使用

    /./{
    H
    $!d
}
x
/AAA/!d
s/\n//

    或者，在命令行上

    sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;s/\n//'
    • 1

相关问题