主页 / unix / 问题 / 433273
Accepted
maddingl
Asked: 2018-03-25 07:15:04 +0800 CST

在 zsh 和 vim 中根据模式更改光标样式

  • 772

我在oh-my-zsh中使用vi-mode和af-magic主题。

我希望光标样式指示我是处于正常模式（块）还是插入模式（光束），无论是 inzsh还是 in vim。

这是我到目前为止所拥有的：

在我的~/.zshrc：

    # vim mode config
    # ---------------

    # Activate vim mode.
    bindkey -v

    # Remove mode switching delay.
    KEYTIMEOUT=5

    # Change cursor shape for different vi modes.
    function zle-keymap-select {
      if [[ ${KEYMAP} == vicmd ]] ||
         [[ $1 = 'block' ]]; then
        echo -ne '\e[1 q'

      elif [[ ${KEYMAP} == main ]] ||
           [[ ${KEYMAP} == viins ]] ||
           [[ ${KEYMAP} = '' ]] ||
           [[ $1 = 'beam' ]]; then
        echo -ne '\e[5 q'
      fi
    }
    zle -N zle-keymap-select

    # Use beam shape cursor on startup.
    echo -ne '\e[5 q'

    # Use beam shape cursor for each new prompt.
    preexec() {
       echo -ne '\e[5 q'
    }

如发现here。

在vim中，我使用Vundle和总站。

使用这些配置，当独立考虑时，两者都可以正常工作zsh。vim但是，当我vim从插入模式zsh进入时，以正常模式开始（应该如此），但仍显示光束形状光标。同样，当我退出时，我回到插入模式，但光标仍然是块状（因为最后一个模式是正常的）。vimvimzshvim

在此之后，当我第一次切换模式（在zsh和中vim）时，光标再次按照应有的方式运行。

如何让它们在进入和退出后也显示正确的光标vim？

我试着把

    autocmd VimEnter * stopinsert
    autocmd VimLeave * startinsert

在我的~.vimrc，但这不会影响光标。

zsh vim

6 个回答

  1. Best Answer

    我认为最好使用precmd()而不是preexec()：

    # .zshrc

_fix_cursor() {
   echo -ne '\e[5 q'
}

precmd_functions+=(_fix_cursor)

    这边走：

    • 你不必改变.vimrc
    • 当您在不执行命令的情况下创建新提示时，光标也已修复
    • 你不必echo -ne '\e[5 q'在你的.zshrc.
    • 18

  2. 这对我来说非常有效，它取自这里：https ://gist.github.com/LukeSmithxyz/e62f26e55ea8b0ed41a65912fbebbe52

    # vi mode
bindkey -v
export KEYTIMEOUT=1

# Change cursor shape for different vi modes.
function zle-keymap-select {
  if [[ ${KEYMAP} == vicmd ]] ||
     [[ $1 = 'block' ]]; then
    echo -ne '\e[1 q'
  elif [[ ${KEYMAP} == main ]] ||
       [[ ${KEYMAP} == viins ]] ||
       [[ ${KEYMAP} = '' ]] ||
       [[ $1 = 'beam' ]]; then
    echo -ne '\e[5 q'
  fi
}
zle -N zle-keymap-select
zle-line-init() {
    zle -K viins # initiate `vi insert` as keymap (can be removed if `bindkey -V` has been set elsewhere)
    echo -ne "\e[5 q"
}
zle -N zle-line-init
echo -ne '\e[5 q' # Use beam shape cursor on startup.
preexec() { echo -ne '\e[5 q' ;} # Use beam shape cursor for each new prompt.

    您可以通过更改以下序列中的数字\e[5 q（5 代表光束，1 代表块）来自定义所需的光标类型（闪烁或不闪烁、|、矩形或 _），如下所示：

    Set cursor style (DECSCUSR), VT520.
0  ⇒  blinking block.
1  ⇒  blinking block (default).
2  ⇒  steady block.
3  ⇒  blinking underline.
4  ⇒  steady underline.
5  ⇒  blinking bar, xterm.
6  ⇒  steady bar, xterm.
    • 6

  3. 只需添加以下行：

    export VI_MODE_SET_CURSOR=true

    到你的~/.zshrc. 在issue #9570的讨论中提到了它。

    • 3

  4. 我找到了一个解决方案：

    我把这个放在我的~/.vimrc：

    autocmd VimEnter * silent exec "! echo -ne '\e[1 q'"
autocmd VimLeave * silent exec "! echo -ne '\e[5 q'"
    • 2

  5. 你也可以使用zle-line-init()

    zle-line-init() {
    zle -K viins # initiate `vi insert` as keymap (can be removed if `bindkey -V` has been set elsewhere)
    echo -ne "\e[5 q"
}

    我认为使用它可以更好地解决这个问题，而不是precmd()或preexec()两者都用于执行命令，而不是修复提示。

    • 0

  6. 以下脚本适用于我。每次启动/退出程序后都会更改光标。

    function _set_cursor() {
    if [[ $TMUX = '' ]]; then
      echo -ne $1
    else
      echo -ne "\ePtmux;\e\e$1\e\\"
    fi
}

# Remove mode switching delay.
KEYTIMEOUT=5

function _set_block_cursor() { _set_cursor '\e[2 q' }
function _set_beam_cursor() { _set_cursor '\e[0 q' }

function zle-keymap-select {
  if [[ ${KEYMAP} == vicmd ]] || [[ $1 = 'block' ]]; then
      _set_block_cursor
  else
      _set_beam_cursor
  fi
}
zle -N zle-keymap-select
# ensure beam cursor when starting new terminal
precmd_functions+=(_set_beam_cursor) #
# ensure insert mode and beam cursor when exiting vim
zle-line-init() { zle -K viins; _set_beam_cursor }
zle-line-finish() { _set_block_cursor }
zle -N zle-line-finish
    • 0

相关问题