主页 / unix / 问题 / 415045
Accepted
Nithin Kumar
Asked: 2018-01-06 10:19:37 +0800 CST

AWK 合并行

  • 772

我有如下输入文件

1
2
3
4
5
6
7
8
9
10

我需要如下输出

1 2
3 4 5
6 7
8 9 10

意思是前两行要连接在一起，然后接下来的三行也要连接在一起。

awk

4 个回答

  1. 我也可以通过以下方式完成工作paste：

    $ seq 10 | paste -s -d $' \n  \n'
1 2
3 4 5
6 7
8 9 10
$

    我在这里使用了 bash (for $'\n')。并seq 10重现您的输入：

    $ seq 10
1
2
3
4
5
6
7
8
9
10
$
    • 2 
  2. #!/usr/bin/awk -f

BEGIN { maxlines=2 ; lc=0 }

{ outputline=outputline " " $0; lc++ }

lc % maxlines == 0 {
  sub(/^ /,"",outputline); # strip unwanted leading space
  print outputline;

  outputline="";
  lc=0;
  maxlines = 5 - maxlines; # flip-flop: 5-2=3, 5-3=2
}

    这在加入和打印 2 或 3 行连续行之间交替。

    输出：

    1 2
3 4 5
6 7
8 9 10

    或使用原始输入数据：

    Unix Linux
Solaris AIX Sco

    或者，使用数组。 awk没有join()功能，所以我们必须提供一个。

    #!/usr/bin/awk -f

BEGIN { maxlines=2 ; lc=0 }

function join(sep,array,       i) {
  result=array[1];
  for (i=2;i<=length(array);i++) result = result sep array[i];
  return result
};

{ lines[++lc]=$0 }

lc % maxlines == 0 {
  print join(" ", lines);
  delete lines;

  lc=0;
  maxlines = 5-maxlines
}
    • 1

  3. 只需完成以下工作awk：

    awk -v step=3 '{l=(!l)?l$0:l" "$0} ++seen==2 && step==3{print l;step++;l=seen=""}
    seen==3{print l;step--;l=seen=""}' infile

    输出：

    1 2
3 4 5
6 7
8 9 10
    • 0
  4. Best Answer

    双 awk 方法：

    $ awk '{printf("%s",$0 (NR%5==0?ORS:":"))}' file1 |awk -F':' '{print $1,$2;print $3,$4,$5}'
1 2
3 4 5
6 7
8 9 10

    线首先以五组连接，每条线用:符号连接。

    即使行包含更多单词，解决方案也有效

    $ cat file2
this is line 1
this is line 2
this is line 3
this is line 4
this is line 5
this is line 6
this is line 7
this is line 8
this is line 9
this is line 10

$ awk '{printf("%s",$0 (NR%5==0?ORS:":"))}' file2 |awk -F':' '{print $1,$2;print $3,$4,$5}'
this is line 1 this is line 2
this is line 3 this is line 4 this is line 5
this is line 6 this is line 7
this is line 8 this is line 9 this is line 10
    • 0

相关问题