puppet：修改配置文件后强制重启服务

通知的替代方法是订阅：

file { "/etc/sshd_config":
    source => "....",
}

service { sshd:
    ensure => running,
    subscribe => File["/etc/sshd_config"],
}

不同之处在于关系是从另一端描述的。例如，你可以让 apache 订阅 /etc/apache/httpd.conf，但是你会创建一个 vhost 文件来通知 apache，因为你的 apache 类不会知道你拥有的每个 vhost。

类似的双端情况适用于 require 和 before。这只是在特定情况下哪个更有意义的问题。

正如 Chad 所提到的，如果您发现 puppet 不断尝试启动您的服务，那么您需要添加一个模式参数，这是一个应用于进程列表的正则表达式。默认情况下，puppet 将停止并开始重新启动服务。如果添加“hasrestart => true”，那么它将使用“restart”参数中指定的命令重新启动服务。

看来我找到了一些东西：

file { "/etc/sshd_config":
    source => "....",
    notify => Service[sshd]
}

service { sshd:
    ensure => running
}

我们将看看它是如何工作的。无论如何，欢迎您对该主题的想法。

（我知道这是一个非常古老的问题，但只是想我会用一种（在我看来）更简单的方法来投入我的两分钱）

也可以随意使用箭头符号：

file { "/etc/sshd_config":
  source => "....",
} ~>
service { sshd:
  ensure => running
}

或者

File['/etc/sshd_config'] ~> Service['sshd']

这适用于 Solaris 10 :)

class sun_cron_root {
    file { "/var/spool/cron/crontabs/root" :
            source => "puppet:///files/cron/sun/sun_cron_root"
            }

    service {
            "cron":
            provider => "smf",
            ensure => running,
            enable => true,
            hasrestart => true,
            subscribe => File["/var/spool/cron/crontabs/root"]
            }

}

有多个等价符号：

通知：

file { '/etc/sshd_config':
    notify => Service[sshd],
}

service { sshd:
    ensure => running
}

订阅：

file { '/etc/sshd_config':
   ...
}

service { sshd:
    ensure => running,
    subscribe => File['/etc/sshd_config'],
}

箭头符号：

File['/etc/sshd_config'] ~> Service['sshd']

链接声明

file { '/etc/sshd_config':
   ...
}
~> service { sshd:
    ensure => running,
}

如果要触发reload而不是restart，请调整服务声明：

service { sshd:
    ensure => running,
    restart => 'pkill -HUP sshd', # if service support such reload
}