Início / computer / Perguntas / 1590890
Accepted
sancho.s ReinstateMonicaCellio
Asked: 2020-10-06 04:08:16 +0800 CST

Exporte o Powerpoint para um único PDF, cada página como uma imagem

  • 772

Eu tenho uma apresentação em Powerpoint. Eu quero transformá-lo em um PDF. Se eu salvar uma cópia e usar PDF, há pelo menos dois problemas que desejo evitar:

  1. O texto é selecionável. Talvez isso possa ser evitado por meio das configurações de segurança do arquivo PDF.

  2. Lembro-me de ver ocasionalmente (e é uma pena que não posso reproduzir agora) que o PDF resultante tem pequenos problemas de organização.

Uma maneira de evitar esses problemas é exportar cada slide como uma imagem pura. Eu posso lidar com essa rota, mas há dois pontos que a tornam um tanto complicada, dos quais pretendo me livrar:

  1. Ao exportar do Powerpoint como jpg (por exemplo), não há opção para evitar a exportação de slides ocultos (isso pode ser feito ao salvar diretamente como PDF).

  2. Ao exportar do Powerpoint como jpg (por exemplo), cada slide é exportado separadamente. O encadeamento de todas as imagens em um pdf deve ser feito manualmente.

Existe alguma maneira de atingir meu objetivo? Acho que poderia escrever código VBA para isso, mas não quero reinventar a roda.

pdf microsoft-powerpoint

2 respostas

  1. Salve uma CÓPIA de sua apresentação como uma apresentação de imagem do PowerPoint. Isso lhe dará um PPTX onde cada slide é uma imagem do slide original.

    Não substitua sua apresentação original ao salvá-la. Depois que os slides forem convertidos em imagens, não será possível convertê-los novamente em slides editáveis.

    Certifique-se de que os slides que estavam ocultos no original permaneçam ocultos na apresentação de imagem salva. Caso contrário, convém ocultá-los novamente antes de salvá-los em PDF.

    • 2
  2. Best Answer

    Após a troca de comentários na resposta de Steve Rindsberg, concluí que o caminho a seguir é com o VBA (o que eu pretendia evitar). Estou postando aqui o código que usei. No momento de escrever o código, ele oferece flexibilidade para adicionar recursos, por exemplo, não exporte slides ocultos.
    Adicionei a concatenação de imagens em um único arquivo PDF (isso também pode ser feito com o Adobe Acrobat, conversor do ImageMagick, etc.)
    Observe que ExportAsFixedFormatrequer ppFixedFormatIntentPrint, caso contrário, a qualidade da saída será perdida novamente.
    Espero que isso seja útil para os outros.

    Sub ppt2images(Optional path As String = "")
    '
    ' If not given, use for the output directory the same as in the original presentation
    '
    On Error GoTo Err_ImageSave

    ' Set paths and file names
    Dim oPres As Presentation
    Set oPres = ActivePresentation
    Dim sImagePath As String
    Dim sPrefix As String
    sPrefix = Split(oPres.Name, ".")(0)
    If (path = "") Then
        path = oPres.path
    End If
    sImagePath = path & "\" & sPrefix
    If Dir(sImagePath, vbDirectory) <> vbNullString Then
        'MsgBox "Folder " & sImagePath & " exist"
    Else
        MkDir (sImagePath)
    End If
   
    ' Get current resolution
    Dim ps As PageSetup
    Set ps = oPres.PageSetup
    Dim lScaleWidth As Long '* Scale Width
    Dim lScaleHeight As Long '* Scale Height
    lScaleWidth = ps.SlideWidth
    lScaleHeight = ps.SlideHeight
    Dim ar As Double
    ar = lScaleWidth / lScaleHeight
    
    ' Set target resolution
    Dim newWidth As Long '* Scale Width
    Dim newHeight As Long '* Scale Height
    newWidth = 4096
    newHeight = newWidth / ar
    
    ' Create new temporary presentation to add generated images as slides
    Dim oPresTmp As Presentation
    ' Create it as not visible
    Set oPresTmp = Presentations.Add(msoFalse)
    ' Copy page size from the source presentation
    With oPresTmp.PageSetup
        .SlideHeight = oPres.PageSetup.SlideHeight
        .SlideWidth = oPres.PageSetup.SlideWidth
    End With
    Dim oSlideNew As Slide '* Slide Object
    Dim oPic As Shape

    ' Export slides
    Dim sImageName As String
    Dim oSlide As Slide '* Slide Object
    Dim img_format As String
    img_format = "png"
    For Each oSlide In oPres.Slides
        With oSlide
            ' If slide is not hidden
            If (.SlideShowTransition.Hidden = msoFalse) Then
                ' Export slide
                sImageName = sImagePath & "\" & sPrefix & "-" & Format$(.SlideIndex, "000") & "." & img_format
                .Export sImageName, img_format, newWidth, newHeight
                ' Add it to the temporary presentation
                Set oSlideNew = oPresTmp.Slides.Add(oPresTmp.Slides.Count + 1, ppLayoutBlank)
                Set oPic = oSlideNew.Shapes.AddPicture(FileName:=sImageName, _
                    LinkToFile:=msoFalse, _
                    SaveWithDocument:=msoTrue, _
                    Left:=0, _
                    Top:=0, _
                    Width:=-1, _
                    Height:=-1)
                    ' width/height of -1 tells PPT to import the image at its "natural" size
            End If
        End With
    Next oSlide
    
    With oPresTmp
        ' Export temp presentation to pdf
        Dim sPDFName As String
        sPDFName = sImagePath & ".pdf"
        .ExportAsFixedFormat sPDFName, ppFixedFormatTypePDF, ppFixedFormatIntentPrint, msoFalse, _
            ppPrintHandoutVerticalFirst, ppPrintOutputSlides, msoFalse
        
        ' Close temp presentation
        .Saved = True
        .Close
    End With

Err_ImageSave:
    If Err <> 0 Then
        MsgBox Err.Description
    End If
End Sub
    • 1

relate perguntas