Sem som - como posso desfazer 'sc delete AudioEndpointBuilder'?

Aqui estão algumas sugestões.

1. Você pode baixar e descompactar o seguinte cmdarquivo em:
   https://user.it.uu.se/%7Ehesc0353/AudiosrvEndpointBuilder.zip

Depois de descompactar, clique com o botão direito do mouse e escolha Run as administrator.

Se você receber a pergunta Overwrite (Yes/No)?, recomendo que sempre digite n(para No ) e clique em Enter, porque responder Sim significa que você substituirá o arquivo de backup que deveria permitir desfazer as alterações no registro - caso isso é algo que você gostaria de fazer.

O conteúdo do script é o seguinte:

@Echo off
:: ---------------------------------------------------------------------------------------
:: https://user.it.uu.se/%7Ehesc0353/AudiosrvEndpointBuilder.zip
:: ---------------------------------------------------------------------------------------
:: If you substantially alter this code - or use just small snippets of it -
:: please make sure to always leave the following 12 lines intact:
 Echo.
 Echo  DISCLAIMER.
 Echo  Read https://stackoverflow.com/legal/terms-of-service/public#warranties !
 Echo  Credit - https://superuser.com/users/1102737/henke
 Echo  This issue has caused me LOTS of frustration and that I have spent many, MANY hours
 Echo  hours on resolving it. So if this cmd file has been helpful, the best way to thank
 Echo  me is to upvote both the question and this answer - if you are allowed to.
 Echo     Link to answer - https://superuser.com/a/1585392
 Echo  (c) Copyright Henke 2022-05-05 - https://superuser.com/users/1102737
 Echo     This answer to How can I undo 'sc delete AudioEndpointBuilder'? is licensed
 Echo  under [CC BY 4.0](https://creativecommons.org/licenses/by/4.0/)
 Echo.
 Echo  = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
 Echo  =  If you DON'T want to run this file, hit CTRL + C, then y, then ENTER!  =
 Echo  = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = = =
 Echo.
 Echo  If you WANT to run it, you need to right-click it and 'Run as administrator'.
 Echo.
:: ---------------------------------------------------------------------------------------
pause

:: Save a backup of the existing registry keys for AudioEndpointBuilder:
%SystemRoot%\System32\reg export^
 HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder^
 %SystemRoot%\BackupOfAudioEndpointBuilder.reg
:: Delete the existing registry keys for AudioEndpointBuilder:
reg delete HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /f
:: Create the registry keys for AudioEndpointBuilder:
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v Description /d^
 @^%%SystemRoot^%%\System32\AudioEndpointBuilder.dll,-205 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v DisplayName /d^
 @^%%SystemRoot^%%\System32\AudioEndpointBuilder.dll,-204 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v ErrorControl /t^
 REG_DWORD /d 1 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v^
 FailureActions /t REG_BINARY /d^
 "80510100000000000000000003000000140000000100000060ea000001000000c0d401000000000000000000" /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v Group /d^
 AudioGroup /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v ImagePath /t^
 REG_EXPAND_SZ /d "%%SystemRoot%%\System32\svchost.exe -k LocalSystemNetworkRestricted -p" /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v ObjectName /d^
 LocalSystem /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v RequiredPrivileges /t^
 REG_MULTI_SZ /d SeChangeNotifyPrivilege /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v^
 ServiceSidType /t REG_DWORD /d 1 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v^
 Start /t REG_DWORD /d 2 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder /v^
 Type /t REG_DWORD /d 32 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder\Parameters /v^
 ServiceDll /t REG_EXPAND_SZ /d ^%%SystemRoot^%%\System32\AudioEndpointBuilder.dll /f
reg add HKLM\SYSTEM\CurrentControlSet\services\AudioEndpointBuilder\Parameters /v^
 ServiceDllUnloadOnStop /t REG_DWORD /d 1 /f

:: Save a backup of the existing registry keys for Audiosrv:
%SystemRoot%\System32\reg export^
 HKLM\SYSTEM\CurrentControlSet\services\Audiosrv %SystemRoot%\BackupOfAudiosrv.reg
:: Delete the existing registry keys for Audiosrv:
reg delete HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /f
:: Create the registry keys for Audiosrv:
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v DependOnService /t^
 REG_MULTI_SZ /d "AudioEndpointBuilder\0RpcSs" /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v Description /d^
 @^%%SystemRoot^%%\System32\audiosrv.dll,-201 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v DisplayName /d^
 @^%%SystemRoot^%%\System32\audiosrv.dll,-200 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v ErrorControl /t^
 REG_DWORD /d 1 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v^
 FailureActions /t REG_BINARY /d^
 "80510100000000000000000003000000140000000100000060ea000001000000c0d401000100000020bf0200" /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v Group /d^
 AudioGroup /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v ImagePath /t^
 REG_EXPAND_SZ /d "%%SystemRoot%%\System32\svchost.exe -k LocalServiceNetworkRestricted -p" /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v ObjectName /d^
 "NT AUTHORITY\LocalService" /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v RequiredPrivileges /t^
 REG_MULTI_SZ /d "SeChangeNotifyPrivilege\0SeImpersonatePrivilege\0SeIncreaseWorkingSetPrivilege" /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v^
 ServiceSidType /t REG_DWORD /d 1 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v^
 Start /t REG_DWORD /d 2 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv /v^
 Type /t REG_DWORD /d 16 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv\Parameters /v^
 ServiceDll /t REG_EXPAND_SZ /d ^%%SystemRoot^%%\System32\Audiosrv.dll /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv\Parameters /v^
 ServiceDllUnloadOnStop /t REG_DWORD /d 1 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\Audiosrv\Security /v Security /t REG_BINARY /d^
 "01000480c0000000cc00000000000000140000000200ac000600000000001400fd01020001010000000000051200000000001800ff010f0001020000000000052000000020020000000014008d010200010100000000000504000000000014008d010200010100000000000506000000000018008d000200010200000000000f0200000001000000000038008d000200010a00000000000f0300000000040000abace86417c3b0f1abc5110bd73b6dc89d8a33d21867214545351283ff23a71d010100000000000512000000010100000000000512000000" /f

:: Create the services:
sc create AudioEndpointBuilder binPath=^
 ^%%SystemRoot^%%"\system32\svchost.exe -k LocalSystemNetworkRestricted" type= share start= auto
sc create Audiosrv binPath=^
 ^%%SystemRoot^%%"\system32\svchost.exe -k LocalServiceNetworkRestricted" type= share start= auto

:Description
 Echo  Please note!
 Echo  - - - - - -
 Echo  '%0' created the AudioEndpointBuilder Audiosrv services
 Echo  in the registry and in services.msc.
 Echo.
 Echo   = = = = = = = = = = = = = = = = = =
 Echo   =  PLEASE RESTART YOUR COMPUTER!  =   I hope your Audio works now. (It should!)
 Echo   = = = = = = = = = = = = = = = = = =
 Echo.
 Echo  -  *  -  *  -
 Echo.
 Echo  Finished! - Press ENTER when you are ready to close this terminal window.
 Echo.
:: ---------------------------------------------------------------------------------------
pause

Se o script acima não restaurar o som do seu computador, pode haver problemas com o arquivo AudioEndpointBuilder.dlle/ou audiosrv.dll. Esses dois arquivos geralmente estão localizados em C:\Windows\System32\. Eles podem estar ausentes ou ter a(s) versão(ões) errada(s) em comparação com a versão atual do Windows 10.
No entanto, a menos que você tenha mexido com esses arquivos, provavelmente esse não será o problema.

Outra razão pela qual o script não recupera seu som pode ser problemas com seus drivers de som. Mas também considero isso improvável. Em Device Managerprocurar Sound, video and game controllers. A maneira mais fácil de instalar os drivers disponíveis mais recentes pode ser deixar o Windows Update fazer isso por você.

2. Você pode tentar atualizar para uma versão posterior do Windows 10. Isso é semelhante a fazer uma instalação limpa do Windows 10. No meu laptop com uma unidade de disco rígido, isso levou cerca de sete horas. Veja, por exemplo:
   Atualização automática para nova atualização de recursos do Windows 10
   Como forçar o Windows 10 a instalar uma atualização
   Ou faça uma pesquisa online, por exemplo, por:
   "Windows 10" "Update & Security" "Update Assistant".

3. Pressione Win ⊞+ R, digite cmd, segure Ctrl+ Shifte pressione Enter. ¹
   Em seguida, execute:

DISM /Online /Cleanup-Image /RestoreHealth

4. Faça uma instalação limpa do Windows 10. Ao fazer isso, você perderá todos os softwares instalados em seu computador, portanto, isso deve ser considerado apenas como último recurso.

Referências

• Script CMD para restaurar as configurações do registro para que o áudio funcione
• Atualização automática para a nova atualização de recursos do Windows 10
• Como forçar o Windows 10 a instalar uma atualização