Início / computer / Perguntas / 1580130
Accepted
John
Asked: 2020-08-24 13:24:57 +0800 CST

AppleScript usa o ID da janela do Safari para criar novas guias

  • 772

Eu tenho um AppleScript que cria um novo documento do Safari e abre vários URLs nessa janela usando um loop de repetição. Gostaria que o script continuasse usando a mesma janela, mesmo que não seja a janela mais à frente.

(O problema é que, se um usuário mudar o foco para outra janela do Safari, esse script abrirá as URLs na janela mais à frente, em vez da janela criada anteriormente.)

Gostaria de resolver esse problema usando o window idse possível, mas preciso de ajuda no script.

Para esse fim, criei o seguinte, mas, novamente, acho que pode haver um problema. Prefiro não obter o id usando front window, pois um usuário pode alterar a janela frontal em um momento inoportuno e o script puxaria o ID da janela errado.

tell application "Safari"
    make new document -- after this what if user changes focus
    set win_ID to id of front window of application "Safari"
end tell

Eu prefiro usar algo como

set win_ID to window id of (make new document)

Mesmo usando o acima, não consegui abrir URLs em uma janela usando seu id de janela e preciso de ajuda com esse script também.

Funcionaria mais ou menos assim:

tell application "Safari"
    open location "https://apple.com" in a new tab in window id xxxx
end tell
safari applescript

2 respostas

  1. Best Answer

    Atualização para abordar as preocupações do uso de:front window

    O exemplo de código AppleScript a seguir garante que a lista de URL s seja aberta na janela de destino , independentemente de sua posição na ordem z das janelas .

    set myURLs to {¬
    "https://apple.com", ¬
    "https://google.com", ¬
    "https://superuser.com", ¬
    "https://example.com"}

set windowName to random number from 1000000 to 9999999
set tmpFileName to "/private/tmp/" & windowName & ".html"
set tmpFileContent to "<html><head><title>" & windowName & "</title></head></html>"

if not my writeToFile(tmpFileContent, tmpFileName, true) then return

tell application "Safari"
    
    make new document with properties {URL:"file://" & tmpFileName}
    set i to 0
    repeat while not (exists (windows whose name is windowName))
        delay 0.1
        set i to i + 1
        if i = 30 then return
    end repeat
    set winID to (id of windows whose name is windowName) as number
    
    make new tab at end of tabs of window id winID with properties {URL:item 1 of myURLs}
    delete first tab of window id winID
    repeat with i from 2 to (length of myURLs)
        make new tab at end of tabs of window id winID with properties {URL:item i of myURLs}
        delay 1
    end repeat
    
end tell

tell application "System Events" to delete file tmpFileName


--  # Handler #

on writeToFile(theData, theFile, overwriteExistingContent)
    try
        set theFile to theFile as string
        if theFile contains "/" then
            set theOpenedFile to open for access theFile with write permission
        else
            set theOpenedFile to open for access file theFile with write permission
        end if
        if overwriteExistingContent is true then set eof of theOpenedFile to 0
        write theData to theOpenedFile starting at eof
        close access theOpenedFile
        return true
    on error
        try
            close access file theFile
        end try
        return false
    end try
end writeToFile

    Observação: role conforme necessário para ver todo o código .

    Notas:

    • O código AppleScript de exemplo atualizado inclui algum tratamento de erros , pois se o arquivo tmp (valor da variável ) não for criado, o script será interrompido sem nenhuma mensagem. Isso pode ser alterado convertendo a instrução em um bloco completo e incluindo um , ou comando apropriado , conforme desejado, seguido pelo comando . tmpFileName if not my writeToFile ... if display alertdisplay dialogdisplay notification return

    • Conforme codificado, isso --> document "Untitled"retorna do make new documentirrelevante, porque com o repeat loop incluído ele espera até que o arquivo HTML seja carregado e pode ser consultado pelo nome real do documento conforme definido pelas tags no documento e garante que a ordem z seja irrelevante.<title>" & windowName & "</title>

    • O repeat loop conforme codificado é escrito para esperar até 3 segundos para o arquivo HTML carregar e deve ser mais do que tempo suficiente. Ajuste se necessário.

    • Optei por abrir mão do uso do do shell script comando conforme utilizado em sua resposta, porém, se preferir utilizá-lo, então:

    Substituir:

    if not my writeToFile(tmpFileContent, tmpFileName, true) then return

    Com:

    set shellCMD to {"echo '", tmpFileContent, "' > '", tmpFileName, "'"} as string
do shell script shellCMD

    Em seguida, remova o on writeToFile(theData, theFile, overwriteExistingContent) manipulador da -- # Handler # seção do código .

    Além disso, se você preferir um do shell script comando para remover o arquivo tmp , o valor da tmpFileName variável , então:

    Substituir:

    tell application "System Events" to delete file tmpFileName

    Com:

    do shell script "rm " & tmpFileName's quoted form

    Resposta original

    O exemplo de código AppleScript a seguir é um exemplo de como abrir uma lista de URLs na mesma janela do Safari , independentemente da ordem das janelas .

    Notas:

    • Não use open location, pois faz parte do Standard Additions , não do Safari . Use a URL propriedade para definir a URL do documento ou guia .
    • Use um listdos URLs e o índice do item da lista ( URL ) na lista .
    • Quando o Safari é instruído a fazê-lo make new document, o novo documento torna-se o front windowdo Safari . Obtenha o window iddo front windowimediatamente após o make new document comando .
    • Para URLs subseqüentes na lista , inicie o repeat loop em 2e use o window idque foi determinado diretamente após a execução do make new document comando .
    set myURLs to {¬
    "https://apple.com", ¬
    "https://google.com", ¬
    "https://superuser.com", ¬
    "https://example.com"}

tell application "Safari"
    
    make new document with properties {URL:item 1 of myURLs}
    set winID to id of front window
    
    repeat with i from 2 to (count myURLs)
        make new tab at end of tabs of window id winID with properties {URL:item i of myURLs}
        delay 1
    end repeat
    
end tell
    • 1

  2. @ user3439894 Aceitei sua resposta - ela responde bem à pergunta. Existe outra maneira - uma maneira hackie de criar um ID para uma janela do Safari.

    Isso permite que os seguintes comandos evitem o uso de "janela frontal" caso a janela que foi criada não esteja mais na frente quando o restante dos comandos começar - duvidoso, mas possível.

    Não tenho certeza se existe uma maneira de dar a uma nova janela algo diferente de "Sem título" como um nome ao criar a janela.

    ## you could use: set x to(time/date combo) instead, and then use variable x in the touch command and "make new document with properties"
do shell script "touch '/private/tmp/uniquename.txt'"
tell application "Safari"
    make new document with properties {URL:"file:///private/tmp/uniquename.txt"}
    set winID to (id of window {name:"uniquename.txt"}) -- this guarantees that the window we just created is the window we are going to add tabs to
    set x to properties of window id winID -- let's take a peek at it's properties
end tell
x

    Respostas:

    tell current application
    do shell script "touch '/private/tmp/uniquename.txt'"
        --> ""
end tell
tell application "Safari"
    make new document with properties {URL:"file:///private/tmp/uniquename.txt"}
        --> document "Untitled"
    get id of window {name:"uniquename.txt"}
        --> 30049
    get properties of window id 30049
        --> {zoomable:true, closeable:true, zoomed:true, class:window, index:1, visible:true, name:"Untitled", miniaturizable:true, id:30049, miniaturized:false, resizable:true, bounds:{0, 23, 800, 423}, current tab:tab 1 of window id 30049, document:document "Untitled"}
end tell
Result:
{zoomable:true, closeable:true, zoomed:true, class:window, index:1, visible:true, name:"Untitled", miniaturizable:true, id:30049, miniaturized:false, resizable:true, bounds:{0, 23, 800, 423}, current tab:tab 1 of window id 30049 of application "Safari", document:document "Untitled" of application "Safari"}
    • 0

relate perguntas