Início / coding / Perguntas / 77888362
Accepted
con
Asked: 2024-01-27 02:34:26 +0800 CST

Datetime do Perl não retornando diferenças corretas no tempo

  • 772

Inspirado em https://perlmaven.com/datetime , estou tentando encontrar o número de horas de diferença entre 2024-01-03T19:00:00 e 2024-01-07T16:00:00 (93 horas).

#!/usr/bin/env perl

use 5.038;
use warnings FATAL => 'all';
use autodie ':default';
use DDP;
use Devel::Confess 'color';
use DateTime;

sub str_to_date ($date) {
    if ($date =~ m/^(\d+) # year
    \-(\d{1,2})           # month
    \-(\d{1,2})           # day
    T
    (\d+)                        # hour
    :
    (\d+)                        # minutes
    :
    (\d+)                        # seconds                  
    /x) {
        return DateTime -> new(
        year  => $1,
        month => $2,
        day   => $3,
        hour    => $4,
        minute=> $5,
        second=> $6,
    );
    } else {
        die "$date failed regex.";
    }
} # later dates are "greater"
my $wed_date = str_to_date('2024-01-03T19:00:00');
say $wed_date->day;
my $sun_date = str_to_date('2024-01-07T16:00:00');
my $diff = $sun_date - $wed_date; # returns a duration object

p $diff;
say $diff->clock_duration->in_units('hours'); # 21, but should be 93
say $diff->in_units('hours'); # 21 again
say $diff->hours; # 21 again
say $sun_date->delta_days($wed_date)->in_units('hours'); # 0
p $diff->deltas;

todos os métodos que encontrei em https://metacpan.org/pod/DateTime::Format::Duration estão fornecendo respostas incorretas.

Alternativamente, se eu remover a análise,

#!/usr/bin/env perl
use 5.038;
use warnings FATAL => 'all';
use autodie ':default';
use DDP;
use Devel::Confess 'color';
use DateTime;

my $wed_date = DateTime->new(
    year => 2024,
    month=>1,
    day=>3,
    hour=>19
);#str_to_date('2024-01-03T19:00:00');
my $sun_date = DateTime->new(
    year=>2024,
    month=>1,
    day=>7,
    hour=>16#my $sun_date = str_to_date('2024-01-07T16:00:00');
);#
say $wed_date->day;

my $diff = $sun_date - $wed_date;

p $diff;
say $diff->clock_duration->in_units('hours'); # 21, but should be 93
say $diff->in_units('hours'); # 21 again
say $diff->hours; # 21 again
say $sun_date->delta_days($wed_date)->in_units('hours'); # 0
p $diff->deltas; # 10

as respostas são idênticas.

o objeto DateTime::Duration parece estar ignorando os dias intermediários e focando apenas na diferença entre as horas.

Como posso obter o número correto de horas entre duas datas?

datetime

2 respostas

  1. a resposta, de acordo com https://metacpan.org/pod/DateTime#How-DateTime-Math-Works

    $sun_date->subtract_datetime_absolute($wed_date)->seconds;

    que é um objeto DateTime::Duration:

    DateTime::Duration  {
    public methods (34): add, add_duration, calendar_duration, clock_duration, clone, compare, days, delta_days, delta_minutes, delta_months, delta_nanoseconds, delta_seconds, deltas, end_of_month_mode, hours, in_units, inverse, is_limit_mode, is_negative, is_positive, is_preserve_mode, is_wrap_mode, is_zero, MAX_NANOSECONDS, minutes, months, multiply, nanoseconds, new, seconds, subtract, subtract_duration, weeks, years
    private methods (8): _add_overload, _compare_overload, _duration_object_from_args, _has_negative, _has_positive, _multiply_overload, _normalize_nanoseconds, _subtract_overload
    overloads: *, +, -, <=>, cmp
    internals: {
        days           0,
        end_of_month   "wrap",
        minutes        0,
        months         0,
        nanoseconds    0,
        seconds        334800
    }
}

    o número de segundos, 334.800, é igual a 93 horas, a resposta correta.

    Obrigado aos comentaristas.

    • 1
  2. Best Answer

    Use ->delta_msem vez de ->subtract_datetime(o método invocado pela subtração).

    Uma duração medida em dias não pode ser convertida em horas, pois nem todos os dias têm o mesmo número de horas. Na verdade, apenas estas conversões são seguras:

    • semanas ⇔ dias
    • horas ⇔ minutos
    • segundos ⇔ nanossegundos

    Como tal, ->in_units( 'hours' )converte apenas os componentes de hora e minuto da duração em horas.

    $sun_date - $wed_dateretorna uma duração de 3 dias e 1260 minutos.
    ->in_units( 'hours' )retorna int( 0 + 1260/60 ) = 21 horas.

    A solução é criar uma duração que consista em horas e/ou minutos em vez de dias.

    $sun_date->delta_ms( $wed_date )retorna uma duração de 5.580 minutos.
    ->in_units( 'hours' )retorna int( 0 + 5580/60 ) = 93 horas.

    • 1

relate perguntas