主页 / dba / 问题 / 341716
Accepted
Marcello Miorelli
Asked: 2024-08-17 04:47:06 +0800 CST

脚本来更改作业的计划，它需要找到与作业关联的计划

  • 772

使用Ola 的备份策略，有一项工作

数据库备份 - 系统数据库已满，如下图所示。

此项工作计划每周日早上运行一次。

一切都很好，已经运行了一段时间了。

现在我需要将其改为每天运行。

使用 ssms 、编写更改脚本并应用它，效果很好。

然而，因为我需要在几十台服务器上完成这项工作，所以我需要一个脚本来找出时间表，然后修改它并重新应用到工作中

我还没有实现它，但我想知道是否有人已经做到了。

在此处输入图片描述

sql-server

2 个回答

  1. Best Answer

    编辑：增强，包括进一步检查与多个作业相关的计划。

    SET NOCOUNT ON ;

DECLARE @name sysname ;
DECLARE @freq_type INT ;
DECLARE @schedule_id INT ;

SET @name = 'DatabaseBackup - SYSTEM_DATABASES - FULL' ;

/* 4 = Daily */
SET @freq_type = 4 ;

SELECT @schedule_id = SJS.schedule_id
FROM msdb.dbo.sysjobschedules AS SJS
INNER JOIN msdb.dbo.sysjobs AS SJ
    ON SJ.job_id = SJS.job_id
INNER JOIN msdb.dbo.sysschedules AS SS
    ON SS.schedule_id = SJS.schedule_id
WHERE SJ.[name] = @name
    AND SS.freq_type <> @freq_type ;

IF @@ROWCOUNT = 1
AND NOT EXISTS ( SELECT 1
                 FROM msdb.dbo.sysjobschedules AS SJS
                 WHERE SJS.schedule_id = @schedule_id
                 HAVING COUNT( DISTINCT SJS.job_id ) > 1 )
    BEGIN
        EXEC msdb.dbo.sp_update_schedule 
            @schedule_id = @schedule_id,
            @freq_type = @freq_type ;
    END
ELSE
    BEGIN
        RAISERROR ('Error : did not find a unique Schedule requiring change', 0, 1) ;
    END ;
    • 3 
  2. USE msdb;

GO

declare @jname sysname='DatabaseBackup - SYSTEM_DATABASES - FULL'
declare @sname nvarchar(128)

set @sname=(select s.name from sysjobs j
    inner join sysjobschedules js on j.job_id = js.job_id
    inner join sysschedules s on js.schedule_id = s.schedule_id
    where j.name = @jname)

If len(@sname)>0 
begin
  exec dbo.sp_update_schedule
       @name = @sname,
       @freq_type = 4;
end
else 
 print 'There is not a schedule defined for the job'
    
GO

    微软

    • 1

相关问题