主页 / coding / 问题 / 79185753
Accepted
Herald Gjura
Asked: 2024-11-14 00:06:35 +0800 CST

ActiveDocument.Paragraphs.Range 的奇怪行为

  • 772

我不是 VBA 专家，但我正在尝试做一些非常简单的事情。我正在尝试从 Word 文档中的每个段落中删除前导空格。

这是我的 VBA 代码：

Function RemoveLeadingSpaces()
    Dim apara As Paragraph

    Application.ScreenUpdating = False
    For Each apara In ActiveDocument.Paragraphs

        'apara.Range.Text = Trim(apara.Range.Text)
        Debug.Print apara.Range.Text

    Next apara
    Application.ScreenUpdating = True
End Function

当我取消注释替换文本的行时，我开始遇到一些奇怪的行为。循环变得无限，并且只会一遍又一遍地应用/替换第一个项目/段落。如果我注释，则调试会按预期打印所有段落。

我做错什么了？

vba

2 个回答

  1. Best Answer

    通过添加两行调试代码，您可以观察到第 5 行（覆盖段落分隔符）不仅修改了循环变量apara，还修改了Paragraph collection。在下一次循环迭代中，将再次选择更新后的第一个段落，从而形成无限循环。

    Function RemoveLeadingSpaces()
    Dim apara As Paragraph
    For Each apara In ActiveDocument.Paragraphs
        apara.Range.Select ' the 1st paragraph is selected
        apara.Range.Text = Trim(apara.Range.Text)
        apara.Range.Select ' the 2nd paragraph is selected
        Debug.Print apara.Range.Text
    Next apara
End Function

    在此处输入图片描述

    请尝试删除前导空格而不影响段落分隔符。

    顺便说一句，如果函数没有返回值，则可以使用Sub过程而不是Function。

    Sub DemoRemoveLeadingSpaces()
    Dim apara As Paragraph, rngPara As Range
    Application.ScreenUpdating = False
    For Each apara In ActiveDocument.Paragraphs
        Set rngPara = apara.Range.Duplicate
        rngPara.MoveEnd wdCharacter, -1
        rngPara.Text = Trim(rngPara.Text)
        Debug.Print apara.Range.Text
    Next apara
    Application.ScreenUpdating = True
End Sub
    • 1

  2. 您甚至不需要宏！您只需要一个通配符查找/替换，其中：

    Find = ^13[ ^s]{1,}
Replace = ^p

    但是，如果您坚持使用宏：

    Sub CleanUp()
Application.ScreenUpdating = False
With ActiveDocument.Range.Find
  .ClearFormatting
  .Replacement.ClearFormatting
  .Format = False
  .Forward = True
  .Wrap = wdFindContinue
  .MatchWildcards = True
  .Text = "^13[ ^s]{1,}"
  .Replacement.Text = "^p"
  .Execute Replace:=wdReplaceAll
End With
Application.ScreenUpdating = True
End Sub

    对于较长的文档，这也比您的代码要快得多。此外，与您的代码不同，查找/替换不会弄乱粗体、下划线、斜体等字符格式。

    • 0

相关问题