主页 / coding / 问题 / 79102958
Accepted
user1377723
Asked: 2024-10-19 00:46:25 +0800 CST

在 XML 文件中添加多个条目

  • 772

我有一个包含 TextBox 和 RichTextBox 的表单。RichTextBox 包含用户要编辑的文本，而 TextBox 包含文本的描述性名称。我想将 RichTextBox 文本及其描述名称保存在 XML 文件中。我使用以下代码来执行此操作。

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button8.Click
    Dim filename As String = "C:\Users\User\Desktop\Test.xml"
    Dim doc As XDocument = Nothing
    Dim RTBText As String = RichTextBox1.Text
    Dim TextBoxText As String = TextBox1.Text
    createNode(TextBoxText, RTBText, doc)
    doc.Save(filename)
End Sub

Private Sub createNode(ByVal varname As String, ByVal varvalue As String, ByRef doc As XDocument)
    Dim identification As String = "<?xml version=""1.0"" encoding=""utf-8"" standalone=""yes""?><Log></Log>"
    doc = XDocument.Parse(identification)
    Dim EntryData As XElement = doc.FirstNode
    Dim EntryDate = System.DateTime.Today.ToString("ddMMyy")
    Dim variables As New XElement("Entry", New Object() {
                                  New XElement("EntryDescription", varname),
                                  New XElement("EntryValue", varvalue),
                                  New XElement("EntryDate", EntryDate)
                                  })
    EntryData.Add(variables)

End Sub

该代码生成以下 XML 文件。

<?xml version="1.0" encoding="utf-8" standalone="yes"?>
<Log>
  <Entry>
    <EntryDescription>This is the TextTextbox Text</EntryDescription>
    <EntryValue>This is RTB Data</EntryValue>
    <EntryDate>181024</EntryDate>
  </Entry>
</Log>

该文件不会有超过几百个条目，这似乎没问题，但我不知道如何向文件添加其他条目。事实上，下一个条目只会覆盖现有条目。完成后，我需要能够搜索 XML 文件的描述性名称，然后检索附带的文本。请有人帮助我找到一个解决方案，使我能够添加其他条目。

xml

2 个回答

  1. Best Answer

    我更喜欢使用 XElement 和 LINQ，

    Public Class Form1

    Private doc As XElement = Nothing
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim filename As String = Environment.GetFolderPath(Environment.SpecialFolder.Desktop)
        filename = IO.Path.Combine(filename, "FOOtest.xml")
        If doc Is Nothing Then
            If IO.File.Exists(filename) Then
                doc = XElement.Load(filename) 'open file if exists
            Else
                doc = <log></log> 'create new
                doc.Save(filename)
            End If
        End If
        createNode(TextBox1.Text, RichTextBox1.Text) 'add node
        doc.Save(filename) 'and save
    End Sub

    Private Sub createNode(varname As String,
                            varvalue As String)
        Dim EntryDate As String = System.DateTime.Now.ToString("ddMMyy")
        Dim variables As XElement
        'build a new entry
        variables = <Entry>
                        <EntryDescription><%= varname %></EntryDescription>
                        <EntryValue><%= varvalue %></EntryValue>
                        <EntryDate>181024</EntryDate>
                    </Entry>
        doc.Add(variables) 'add to existing
    End Sub
End Class
    • 0

  2. 使用 XmlSerialization，

    为您的数据定义一个模型。您可以传递日志条目对象，甚至是日志。

    <XmlRoot>
Partial Public Class Log
    <XmlElement("Entry")>
    Public Property Entries As List(Of LogEntry)
    Public Sub New()
        Entries = New List(Of LogEntry)()
    End Sub
End Class
Partial Public Class LogEntry
    Public Property EntryDescription As String
    Public Property EntryValue As String
    Public Property EntryDate As String
    Public Sub New()
    End Sub
    Public Sub New(entryDescription As String, entryValue As String, entryDate As String)
        Me.EntryDescription = entryDescription
        Me.EntryValue = entryValue
        Me.EntryDate = entryDate
    End Sub
End Class

    Imports System.IO
Imports System.Xml.Serialization

    Private xmlPath As String = "Test.xml"

Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Await AddToLogAsync(TextBox1.Text, RichTextBox1.Text, Date.Today.ToString("ddMMyy"))
End Sub

Private Sub AddToLog(entryDescription As String, entryValue As String, entryDate As String)
    Dim log As Log
    Dim serializer As New XmlSerializer(GetType(Log))
    If File.Exists(xmlPath) Then
        Using sr As New StreamReader(xmlPath)
            log = DirectCast(serializer.Deserialize(sr), Log)
        End Using
    Else
        log = New Log()
    End If
    log.Entries.Add(New LogEntry(entryDescription, entryValue, entryDate))
    Using sw As New StreamWriter(xmlPath)
        serializer.Serialize(sw, log)
    End Using
End Sub

Private Function AddToLogAsync(entryDescription As String, entryValue As String, entryDate As String) As Task
    Return Task.Run(New Action(Sub() AddToLog(entryDescription, entryValue, entryDate)))
End Function

    您可以调用同步版本

    AddToLog(TextBox1.Text, RichTextBox1.Text, Date.Today.ToString("ddMMyy"))

    但这会在您的 UI 上运行（就像您现在所做的一样）。异步版本不会在读取和写入时冻结您的 UI。

    • 0

相关问题