主页 / coding / 问题 / 79041113
Accepted
autio
Asked: 2024-10-01 05:48:38 +0800 CST

同一个文件的两个不同包中出现了两次用“my”声明的变量

  • 772

我已经很久没有用 Perl 编写任何代码了。现在我又开始编写代码了，在单个“.pm”文件中编写两个包时遇到了一个有趣的情况。到目前为止，我认为如果我在一个文件中定义两个包（例如 ConfigData 和 RuntimeData），我可以为每个包定义一个具有相同名称（例如 my $instance）的变量（用“my”声明），而不会发生冲突。作为示例，下面是一段最简洁的代码来说明这一点：

package Jabs::ConfigData;
use strict;
use warnings;

my $instance;
sub new {
        my ($class) = @_;
        unless (defined $instance) {
                $instance = bless {}, $class;
        }
        return $instance;
}
1;  # End of 'ConfigData'

package Jabs::RuntimeData;
use strict;
use warnings;

my $instance;
sub new {
        my ($class) = @_;
        unless (defined $instance) {
                $instance = bless {}, $class;
        }
        return $instance;
}
1;  # End of 'RuntimeData'

我调用了 perl -c test2.pm 并收到以下消息作为反馈：

"my" variable $instance masks earlier declaration in same scope at test2.pm line 27.
test2.pm syntax OK

现在我不清楚为什么范围应该相同。因为'我的 $instance 是在两个不同的包中定义的。我使用的是 Ubuntu 24.04 LTS 和 Perl5（修订版 5 版本 38 颠覆版 2）

有人能为我解释一下我的理解问题吗？

perl

2 个回答

  1. Best Answer

    相关的perldoc -f my说：

    my 将列出的变量声明为封闭块、文件或 eval 的本地（词汇上）。

    形式的 package 关键字package NAME不包含这样的范围。尽管 package 的文档提到你可以使用块声明包，例如package NAME BLOCK。下面是我对此类块的演示。

    perldoc perlmod详细说明：

    package 语句只影响动态全局符号，包括子程序名称和使用 local() 的变量，但不影响使用 my()、our() 或 state() 创建的词法变量。

    use strict;
use warnings;
use feature 'say';

package Conf {  # <-- block start
    use strict;
    use warnings;
    
    my $instance;
    sub new {
            my ($class) = @_;
            unless (defined $instance) {
                    $instance = bless {}, $class;
            }
            $instance->{foo} = "Confs";
            return $instance;
    }
    1;
} # <-- block end END OF CONF

package eData { # <-- block start
    use strict;
    use warnings;
    
    my $instance;
    sub new {
        my ($class) = @_;
        unless (defined $instance) {
                $instance = bless {}, $class;
        }
        $instance->{foo} = "eDatas";
        return $instance;
    }
    1;
} # <-- block end END OF EDATA

my $c1 = Conf->new;    # loads the first $instance 
my $c2 = eData->new;   # loads the other $instance, different variable and scope

say $c1->{foo};
say $c2->{foo};

    输出：

    Confs
eDatas
    • 4

  2. 简而言之，包变量和词法变量是两个独立的变量跟踪系统，彼此之间没有任何关系。

    包变量实际上是全局变量。只要您知道完全限定的包名称（例如main::foo），它就会存在于程序中的所有时间和位置。该package语句仅更改要使用的默认包。local临时替换范围（包含块或文件）中包变量的值。

    词法变量完全由包含声明（）的范围（包含块或文件）控制my。

    就您而言，两个实例都my $instance出现在同一范围（文件）中。

    但是，看起来您正在尝试创建两个单例类，您可以在其中返回已经创建的东西或在第一次使用时创建它。

    Perl v5.10state允许您将该变量移入子例程。这是一个持久词汇变量。而且，//（定义或）允许您使用二进制赋值来简化事情：

    use v5.12;

package Foo { # block package needs v5.12, not necessary for problem
    sub new {
            state $instance; # needs v5.10;
            return $instance //= bless {}, $_[0];
    }
}

    在 v5.10 之前，您可以通过new在包含 的范围内定义 来执行相同的操作$instance。现在$instance仅存在于该范围内：

    
package Foo;
    {
    my $instance;
    sub new {
            return $instance if defined $instance;
            $instance = bless {}, $_[0];
        }
    }

package main;

...
    • 1

相关问题