主页 / coding / 问题 / 78873091
Accepted
yorel
Asked: 2024-08-15 06:25:02 +0800 CST

配置相关目录中的 add_custom_command OUTPUT

  • 772

我想要在每个配置构建目录中生成文件：

add_executable(test_generator_gen test_generator.cpp)
target_compile_definitions(test_generator_gen PRIVATE GENERATE)
target_link_libraries(test_generator_gen YOMM2::yomm2)

add_custom_command(
    OUTPUT ${GENERATED_FILES}
    DEPENDS test_generator_gen
    COMMAND test_generator_gen
    WORKING_DIRECTORY $<TARGET_FILE_DIR:test_generator_gen>
)

文件生成在我想要的位置（例如./builds/headers-only/tests/Debug/test_generator_slots.hpp和另一个文件）。我的问题是，我应该输入什么${GENERATED_FILES}？如果我输入"${CMAKE_CURRENT_BINARY_DIR}/test_generator_slots.hpp"，我就是在欺骗cmake，文件会一次又一次地生成。我尝试了对我来说似乎很自然的方法：

add_custom_command(
    OUTPUT $<TARGET_FILE_DIR:test_generator_gen>/test_generator_slots.hpp
    DEPENDS test_generator_gen
    COMMAND test_generator_gen
    WORKING_DIRECTORY $<TARGET_FILE_DIR:test_generator_gen>
)
# ...

...但我收到一个错误：

CMake Error at tests/CMakeLists.txt:95 (add_custom_command):
[cmake]   Error evaluating generator expression:
[cmake] 
[cmake]     $<TARGET_FILE_DIR:test_generator_gen>
[cmake] 
[cmake]   No target "test_generator_gen"

我很困惑。为什么同一命令中的同一生成器表达式对于某些参数可接受，而对于其他参数则不可接受？我该如何正确指定 OUTPUT？

cmake 3.22.1

cmake

1 个回答

  1. Best Answer

    虽然错误消息看起来很混乱，但文档很清楚：

    参数OUTPUT可以使用一组受限制的生成器表达式。不允许使用依赖于目标的表达式。

    众所周知，对于多配置生成器，可执行文件和库的默认输出目录名称与配置名称相同。因此，您可以使用$<CONFIG>表达式来表示它：

      OUTPUT ${CMAKE_BINARY_DIR}/$<CONFIG>/test_generator_slots.hpp

    为了使项目能够与多配置和单配置生成器一起工作，您需要使用if：

    if(CMAKE_CONFIGURATION_TYPES)
  # Multi-configuration generator
  set(output_dir ${CMAKE_BINARY_DIR}/$<CONFIG>)
else()
  # Single-configuration generator
  set(output_dir ${CMAKE_BINARY_DIR})
endif()
add_custom_command(
  OUTPUT ${output_dir}/test_generator_slots.hpp
  ...
)

    或者，您可以明确设置CMAKE_RUNTIME_OUTPUT_DIRECTORY变量来控制可执行文件的输出目录。并在需要引用该目录时使用该变量：

    if(CMAKE_CONFIGURATION_TYPES)
  # Multi-configuration generator
  #
  # Explicitly use generator expression,
  # so CMake won't automatically append the subdirectory with a config name.
  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/$<CONFIG>/bin)
else()
  # Single-configuration generator
  #
  # While it is allowable to create config-specific directory,
  # we don't do that: every configuration already has its own build tree.
  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
endif()

# The executable will be created in the directory specified by
# CMAKE_RUNTIME_OUTPUT_DIRECTORY variable.
add_executable(test_generator_gen test_generator.cpp)


add_custom_command(
  OUTPUT ${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/test_generator_slots.hpp
  ...
)
    • 1

相关问题