主页 / coding / 问题 / 78851881
Accepted
HigoChumbo
Asked: 2024-08-09 16:45:32 +0800 CST

仅删除 VSTACK 输出中的连续空白

  • 772

我经常使用 VSTACK 列并使用 FILTER 删除空结果，如下所示：

FILTER(VSTACK(<filtered_column_1>;<filtered_column_2>);
VSTACK(<filtered_column_1>;<filtered_column_2>)<>0)

但我遇到过一种情况，我实际上想保留不连续的空白。

未过滤的 VSTACK 输出：

1
2
<blank>
<blank>
<blank>
2
2
3
<blank>
3

所需的已过滤 VSTACK 输出：

1
2
<blank>
2
2
3
<blank>
3

从技术上讲，将每个值与前一个值进行比较应该很容易，但我的问题是我不知道如何在 FILTER“包含”参数中引用 VSTACK 输出列进行比较，特别是考虑到我作为参数提供给 VSTACK 的列不是可引用的列而是过滤后的列本身。

FILTER(VSTACK(<filtered_column_1>;<filtered_column_2>);
<what do I do here in the "include" argument?>)

有什么想法吗？

excel

3 个回答

  1. Best Answer

    尝试以下公式-

    =LET(x,VSTACK("",1,2,"","","",2,2,3,""),
z,MAP(SEQUENCE(ROWS(x)),LAMBDA(y,IF(AND(INDEX(x,y)="",INDEX(x,y-1)=""),FALSE,TRUE))),
FILTER(x,z))

    VSTACK("",1,2,"","","",2,2,3,"")用您的公式替换VSTACK()。

    在此处输入图片描述

    • 3

  2. 从列中删除连续的空白

    • Rory在您的评论中提出了类似的观点。
    =LET(fc,A2:A11,sc,C2:C11,
    st,VSTACK(fc,sc),
    d,IF(st="","",st),
    dn,d="",
    ds,VSTACK(FALSE,DROP(dn,-1)),
    r,FILTER(d,dn*ds=0),
    r)

    在此处输入图片描述

    • 如果不需要步骤d（防止空白显示为零），请输入公式st并d删除st。

    • 将最底部的内容替换r为任何其他变量以查看其包含的内容。

    • 您可以在名称管理器中创建 Lambda 函数，例如RemoveCB使用以下公式：

      =LAMBDA(array,LET(dn,array="",FILTER(array,dn*VSTACK(FALSE,DROP(dn,-1))=0)))

    • 然后，您可以在堆积列上使用它，例如H2#（在屏幕截图中），使用以下公式：

      =RemoveCB(H2#)
    • 1

  3. 类似于：

    =FILTER(<arr>,SCAN(0,<arr>="",LAMBDA(x,y,(x+y)*y))<2)
    • 1

相关问题