主页 / coding / 问题 / 77558754
Accepted
eespie
Asked: 2023-11-28 01:14:05 +0800 CST

提取带有英文网站的维基数据公司

  • 772

我正在尝试查询拥有 Linkedin 标识符、ISINS、LEI 或英文网站的企业。如果可能的话，我只想要每个公司一行数据。

我正在努力解决最后一部分，我想我成功地确定了我只想填充英文网站，但实际的 URL 并未填充在结果中。

SELECT DISTINCT ?item ?itemLabel ?linkedin ?isin ?lei ?website WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  {
    SELECT DISTINCT ?item ?linkedin ?isin ?lei ?website WHERE {
      ?item wdt:P31 wd:Q4830453.
      {
      ?item wdt:P4264 ?linkedin.}
      UNION
      {
      ?item wdt:P946 ?isin.}
      UNION
      {
      ?item wdt:P1278 ?lei.}
      UNION
      {
      ?item wdt:P856 ?statement0.
      ?statement0 p:P856 [ps:P856 ?website ; pq:P407 wd:Q1860] }

    }
    LIMIT 100
  }
}

上述查询的结果

其他数据正在填充，但网站没有。我还获得了每个公司的多条记录。

sparql

1 个回答

  1. Best Answer

    对于与网站有关的内容，请注意

    ?item wdt:P856 ?statement0.
?statement0 p:P856 [ps:P856 ?website ; pq:P407 wd:Q1860]

    是错的。只需使用?item p:P856 [ps:P856 ?website ; pq:P407 wd:Q1860] .. 查看Wikidata:SPARQL 教程§限定符以了解如何查询限定符。

    您可以通过以下方式更正您的查询：首先仅选择?item具有至少一个此类语句 (using UNION)，然后使用 usingOPTIONAL获取所有且仅实际为每个 指定的语句?item。

    结果查询将类似于：

    SELECT DISTINCT ?item ?itemLabel ?linkedin ?isin ?lei ?website WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  OPTIONAL { ?item wdt:P4264 ?linkedin . }
  OPTIONAL { ?item wdt:P946 ?isin . }
  OPTIONAL { ?item wdt:P1278 ?lei . }
  OPTIONAL { ?item p:P856 [ps:P856 ?website ; pq:P407 wd:Q1860] . }
  {
    SELECT DISTINCT ?item WHERE {
      ?item wdt:P31 wd:Q4830453 .
      { ?item wdt:P4264 ?linkedin . }
      UNION
      { ?item wdt:P946 ?isin . }
      UNION
      { ?item wdt:P1278 ?lei . }
      UNION
      { ?item p:P856 [ps:P856 ?website ; pq:P407 wd:Q1860] . }
      hint:SubQuery hint:runOnce true .
    }
    LIMIT 100
  }
  hint:Prior hint:runFirst true .
}

    注意：

    1. 如果为同一属性指定了多个值，您仍将获得每个公司的多行。例如，苹果有多个网站。在这种情况下，要仅获取 Apple 的一行，您可以随机选择一个网站（或您喜欢的任何标准），也可以使用 聚合它们GROUP_CONCAT。
    2. 在子查询中使用LIMIT 100您可能会得到不完整的结果（例如，同一家公司可能同时拥有 P4264 和 P946，但可能只有第一个出现在前 100 个结果中）。为了解决此问题，您应该移出该LIMIT命令。
    • 3

相关问题