主页 / coding / 问题 / 77482909
Accepted
Sam
Asked: 2023-11-15 02:08:24 +0800 CST

添加 1 位数字（不包括 0x）替换最后 4 位数字

  • 772

我有以下文件（test.txt），我想更改逻辑如下：

0 becomes 1
1 becomes 2 
2 becomes 3 
3 becomes 4
4 becomes 5
5 becomes 6 
6 becomes 7 
7 becomes 8 
8 becomes 9
9 becomes 0

$ cat test.txt
69|1074330570|1,sip:+121345633210x3Bverstat=TN-Validation-Passed|tel:+12134565534|0
69|1077822111|2,;tel:+12223120011~sip:[email protected];|sip:[email protected]|0

我想更改最后 4 位数字，但是当 x 紧邻 0x 时，则 0 不算数。例如：在第一行“+121345633210x”中，最后 4 个是 3321。在第二行“+12223120011”中，最后 4 个是 0011 和“+12223120051”，最后 4 个是 0051 输出应如下所示：

69|1074330570|1,sip:+121345644320x3Bverstat=TN-Validation-Passed|tel:+12134566645|0
69|1077822111|2,;tel:+12223121122~sip:[email protected];|sip:[email protected]|0

它需要排除“+1”，然后计算“10”位数字，我想在其中替换第三列和第四列中的最后 4 位。

121345633210 becomes 121345644320 / 12134565534 becomes 12134566645
12223120011  becomes 12223121122  / 12223120051 becomes 12223121162 / 13123120022 becomes 13123121133

当列只是一个数字时，我使用了以下逻辑。但在这种情况下，它还有其他内容，因此下面的逻辑不起作用，但通过添加 1 位数字来转换数字是正确的。

awk -F"|" -v OFS="|" '
NR>0 {                                                      
    for (i=3;i<=4;i++) {                                   
        str = substr($i, 1, length($i) - 4)                 
        for (j = length($i) - 3; j <= length($i); j++) {    
            str = str (substr($i, j, 1) + 1) % 10           
        }
        $i = str                                            
    }
} 
1'
linux

3 个回答

  1. 使用gnu-awk，您可以执行以下操作：

    awk '
function repl(s,  i, r, ch) {
   for (i=1; i<=length(s); ++i) {
      ch = substr(s,i,1)
      r = r (ch == 9 ? 0 : ch+1)
   }
   return r
}
BEGIN {FS=OFS="+"}
{
   for (j=2; j<=NF; ++j) {
      if (match($j, /^([0-9]+)([0-9]{4})(0x|[^x0-9]|$)(.*)/, a))
         $j = a[1] repl(a[2]) a[3] a[4]
   }
} 1' file

69|1074330570|1,sip:+121345644320x3Bverstat=TN-Validation-Passed|tel:+12134566645|0
67|1077822111|2,;tel:+12223121122~sip:[email protected];|sip:[email protected]|0
    • 3
  2. Best Answer

    假设：

    • a+仅显示在第三/第四字段中，然后仅显示在电话号码的前面

    一种awk方法：

    awk '
BEGIN { FS=OFS="+" }                               # split input on "+"
      { for (i=2; i<=NF; i++) {                    # loop through fields that start with a phone number
            oldfld = $i                            # save current field
            $i = ""                                # initialize new field
            d1 = substr(oldfld,1,1)                # get 1st digit
            len = (d1 == 1 ? 7 : 6)                # determine length of phone prefix
            $i = substr(oldfld,1,len)              # save everything up to the phone prefix

            for (j=(len+1); j<=(len+4); j++) {     # loop through last 4 digits of phone number
                x = substr(oldfld,j,1)             # get current digit
                $i = $i (x==9 ? 0 : x+1)           # increment and add to new field
            }

            $i = $i substr(oldfld,len+4+1)         # save rest of old field
         }
      }
1                                                  # print current line
' test.txt

    这会生成：

    69|1074330570|1,sip:+121345644320x3Bverstat=TN-Validation-Passed|tel:+12134566645|0
69|1077822111|2,;tel:+12223121122~sip:[email protected];|sip:[email protected]|0
    • 3

  3. 使用 GNU awk 作为 match() 的第三个参数：

    $ awk '{
    head = ""
    while ( match($0,/([^+]+\+[0-9]{7})([0-9]{4})/,a) ) {
        digs = ""
        for ( i=1; i<=4; i++ ) {
            digs = digs ((substr(a[2],i,1) + 1) % 10)
        }
        head = head a[1] digs
        $0 = substr($0,RSTART+RLENGTH)
    }
    print head $0
}' test.txt
69|1074330570|1,sip:+121345644320x3Bverstat=TN-Validation-Passed|tel:+12134566645|0
69|1077822111|2,;tel:+12223121122~sip:[email protected];|sip:[email protected]|0

    这会产生预期的输出，而无需仅测试第三个或第四个字段，也无需测试，因为0x除了 3 或 4 之外的字段中没有与目标正则表达式匹配的字符串，尽管您说忽略后面的0，x但实际上您是只需始终更改前 11 位数字，0后面的数字x就是第 12 位数字。

    您可以使用任何 POSIX awk 执行相同的操作：

    awk '{
    head = ""
    while ( match($0,/\+[0-9]{11}/) ) {
        digs = ""
        for ( i=1; i<=4; i++ ) {
            digs = digs ((substr($0,RSTART+RLENGTH-5+i,1) + 1) % 10)
        }
        head = head substr($0,1,RSTART+RLENGTH-5) digs
        $0 = substr($0,RSTART+RLENGTH)
    }
    print head $0
}' test.txt
    • 3

相关问题