主页 / coding / 问题 / 77180361
Accepted
PCM
Asked: 2023-09-26 21:15:15 +0800 CST

执行下一条sql语句

  • 772

在我的数据库中，表：

  • test1--不存在
  • 测试2--存在
  • 测试3--存在

运行下面的块时，它会为 test1 抛出“表不存在”错误。但是，尽管出现错误，我还是想为 test2 和 test3 运行以下 drop 语句，因为对于我的情况，“不存在”对我来说很好，因为我将在下一步中创建所有 3 个表。

set serveroutput ON;
BEGIN
    begin
    EXECUTE IMMEDIATE 'drop table test1';
    dbms_output.put_line('test1 dropeed successfully');
    EXECUTE IMMEDIATE 'drop table test2';
    dbms_output.put_line('test2 dropped successfully');
    EXECUTE IMMEDIATE 'drop table test3';
    dbms_output.put_line('test3 dropped successfully');
    exception
        when others then
            dbms_output.put_line('Error >> '|| SQLERRM ||' -->'|| dbms_utility.format_error_backtrace);
    end;
end;

期望：-它也应该删除 test2 和 test3，即使我们得到 test1 的表不存在错误。

plsql

2 个回答

  1. 您需要显式捕获“表不存在”错误并忽略它，您可以这样做：

    DECLARE
  PROCEDURE drop_table(table_name IN VARCHAR2) IS
  BEGIN
    EXECUTE IMMEDIATE 'DROP TABLE ' || table_name;
    dbms_output.put_line(table_name || ' dropped successfully');
  EXCEPTION
    WHEN OTHERS THEN
    IF SQLCODE != -942
    THEN
      RAISE;
    END IF;
  END drop_table;
BEGIN
  drop_table('test1');
  drop_table('test2');
  drop_table('test3');
EXCEPTION
  WHEN OTHERS THEN
    dbms_output.put_line('Error >> ' || SQLERRM || ' -->' || dbms_utility.format_error_backtrace);
END;
/

    请注意，我创建了一个删除表的子过程；这避免了一遍又一遍地重复相同的逻辑。

    • 2
  2. Best Answer

    您需要捕获每个 drop 语句的异常：

    SET serveroutput ON SIZE 999999
CLEAR screen
DECLARE
  table_or_view_dne EXCEPTION;
  PRAGMA EXCEPTION_INIT (table_or_view_dne, -942);
BEGIN
   BEGIN
     EXECUTE IMMEDIATE 'DROP TABLE test1';
   EXCEPTION WHEN table_or_view_dne THEN
     NULL;
   END;
   BEGIN
     EXECUTE IMMEDIATE 'DROP TABLE test2';
   EXCEPTION WHEN table_or_view_dne THEN
     NULL;
   END;
   BEGIN
     EXECUTE IMMEDIATE 'DROP TABLE test3';
   EXCEPTION WHEN table_or_view_dne THEN
     NULL;
   END;
  END;
/
    • 1

相关问题