主页 / coding / 问题 / 76970245
Accepted
Rostyslav Malenko
Asked: 2023-08-24 22:18:44 +0800 CST

Terraform 模板不会按值替换变量

  • 772

我想按值填充模板，但我的内容与模板相同。

文件中的结果应该是这样的hosts.yaml。模板尚未完成，将进行编辑。

rnd_hetzner:
  hosts:
    rnd.test:
      ansible_port: 22
      ansible_host: 1.1.2.3

模板：

# Ansible Inventory
---

all:
  hosts:
{% for instance, details := instances_ips.value %}
    {{ instance }}:
      ansible_host: {{ details.external_ip }}
{% endfor %}

  children:
    all_servers:
      hosts:
{% for instance, _ := instances_ips.value %}
        {{ instance }}
{% endfor %}

地形

locals {
  instances_ips = {
    "value" : {
      "app-server" : {
        "external_ip" : "1.27.1.1"
      },
      "db-server" : {
        "external_ip" : "1.24.9.1"
      }
    }
  }
}

resource "local_file" "ansible_inventory" {
  content = templatefile("${path.module}/templates/ansible_inventory.tpl",
    {
      instances_ips = jsonencode(local.instances_ips)
    }
  )
  filename = "${path.module}/templates/hosts.yaml"
}
terraform

2 个回答

  1. Best Answer

    遵循文档中有关如何生成有效 JSON 或 YAML 的建议templatefile，这是一种惯用的方法。

    该模板包含对yamlencode使用 Terraform 自己的表达式语言描述的数据结构的单个调用。这确保结果始终是有效的 YAML，无需特殊转义：

    # Ansible Inventory
---
${yamlencode({
  hosting = {
    hosts = {
      for inst in instancesips : inst.hostname => {
        ansible_port = 222
        ansible_host = inst.external_ip
      }
    }
  }
})}

    Terraform 配置类似于以下内容：

    data "vultr_instance" "instance_ip" {
  for_each = var.instance
  filter {
    name   = "label"
    values = ["${each.key}.${var.domain}"]
  }
}

locals {
  ips = {
    for k, v in data.vultr_instance.instance_ip : k =>
    {
      hostname    = v.hostname
      external_ip = v.main_ip
    }
  }
}

resource "local_file" "ansible_inventory" {
  content = templatefile("${path.module}/templates/ansible_inventory.tpl",
    {
      instancesips = local.ips
    }
  )
  filename = "${path.module}/templates/hosts.yaml"
}

    还值得考虑提供者文档中的警告注释hashicorp/local，它提供了local_file上面使用的资源类型：

    Terraform 主要处理远程资源，这些资源的寿命比单次 Terraform 运行的寿命长，因此本地资源有时可能会违反其假设。这里的资源最好谨慎使用，因为根据本地状态可能会很难在许多不同的本地系统上应用相同的 Terraform 配置，而本地资源可能不普遍可用。有关详细信息，请参阅每个资源中的具体注释。

    具体来说local_file：

    使用本地文件时，每次在不存在该文件的新计算机上应用配置时，Terraform 都会检测到该资源已被删除，并将生成一个差异以重新创建该文件。在许多不同用户或自动化系统内经常应用配置的环境中，这可能会导致差异中的“噪音”。

    在适当的时候忽略这些警告是可以的，但这确实意味着这种 Terraform 配置的行为与 Terraform 用户对其他提供者的期望不匹配：成功运行后期望状态和实际状态应该收敛，因此未来的计划terraform apply将除非所需的状态发生变化，否则为空。local_file.ansible_inventory使用此配置的任何人都需要接受培训，以期望看到 Terraform 建议在新工作目录中的每次运行中创建，即使所需的状态没有以其他方式更改。

    • 1

  2. 感谢大家。我找到了解决办法。

    我得到这个 JSON

    instances_ips = {
  "app-server" = {
    "external_ip" = "1.2.3.4"
    "hostname" = "app-server.ja.link"
    "internal_ip" = "10.0.0.4"
  }
  "db-server" = {
    "external_ip" = "4.5.6.7"
    "hostname" = "db-server.ja.link"
    "internal_ip" = "10.0.0.3"
  }
}

    在本地.ips中

    data "vultr_instance" "instance_ip" {
  for_each = var.instance
  filter {
    name   = "label"
    values = ["${each.key}.${var.domain}"]
  }
}

locals {
  ips = {
    for k, v in data.vultr_instance.instance_ip : k =>
    {
      hostname    = v.hostname
      external_ip = v.main_ip
    }
  }
}

resource "local_file" "ansible_inventory" {
  content = templatefile("${path.module}/templates/ansible_inventory.tpl",
    {
      instancesips = local.ips
    }
  )
  filename = "${path.module}/templates/hosts.yaml"
}

    我现在的模板是：

    # Ansible Inventory
---
hosting:
  hosts:
  %{~ for inst in instancesips  ~}
    ${inst.hostname}:
      ansible_port: 22
      ansible_host: ${inst.external_ip}
  %{~ endfor ~}
    • 0

相关问题