使用终端命令对 libreoffice calc（电子表格）进行数据操作

最简单的方法是以标准 CSV 格式从 libreoffice 中保存文件，通常以“,”作为分隔符并在 (") 中引用文本，并这样保存公式。您的数据应如下所示：

7,444,5555,99,"bcdef"
22,444,5555,99,"bcdef"

然后，您可以使用一个简单的 awk 命令（例如）来操作它。您可以在字段中包含以“=”开头的公式。例如，

5,99,"=(B5*(B1/A1))"

然后，您在 libreoffice 中读取此 .csv 文件。通常它应该保留公式。

这是一个示例awk脚本，用于将文件操作example.csv成文件new.csv，替换您指定的列，其中 Cn 具有公式 ((An+Bn)*C5)。

awk -F, <example.csv >new.csv '
NR<=4 { printf "%s,%s\n",$1,$4 }
NR==5 { printf "%s,%s,\"%s\"\n",$1,$4,"=(B5*(B1/A1))" }
NR>=6 { printf "%s,%s,\"=((A%d+B%d)*C%d)\"\n",$1,$4,NR,NR,5; }
'

您可以将 new.csv 转换为 .ods：

libreoffice --convert-to ods new.csv

如果您的数据包含“,”和 (")，您需要更改各处使用的分隔符。

（要将带有公式的单元格保存为 csv，请执行以下操作：另存为，文件类型文本 CSV，勾选编辑过滤器设置，保存，字段选项：勾选保存单元格公式，勾选引用所有文本单元格。）

我查看了您的示例 data.csv 文件，并在我的讨论中将其复制到 example.csv。我删除了第 1 行“A、B、C、D、E”（列标题），因为这使得更难解释文件中行号与表中行的对应关系。我用这个 sed 命令做了这个：

sed -i '1{/A,B,C/d}' example.csv

如果需要，您可以在最后恢复标头：

sed -i '1i\A,B,C' new.csv

如果您想在 libreoffice 之外实际进行公式运算，您可以按如下方式在 awk 中进行。awk 每次读取一行数据并执行 {} 中的每个命令。$1 设置为第 1 列，依此类推（如 -F，表示列由“,”分隔）。我们可以将这些值保存在一个由行号索引的数组中，例如 A[NR]=$1 将行NR（当前行）的第 1 列（A 列）保存在数组 A 中。C[NR] 可以设置为计算结果. 然后我们可以在后面的行中再次使用它们：

awk -F, <example.csv >new.csv '
      { A[NR]=$1; B[NR]=$4 }
NR<=4 { printf "%s,%s\n",A[NR],B[NR] }
NR==5 { C[NR] = B[5]*(B[1]/A[1]); printf "%s,%s,%s\n",A[NR],B[NR],C[NR] }
NR>=6 { C[NR] = (A[NR]+B[NR])*C[5]; printf "%s,%s,%s\n",A[NR],B[NR],C[NR] }
'