主页 / ubuntu / 问题 / 1408278
Accepted
Hovlar
Asked: 2022-05-13 20:57:18 +0800 CST

转义序列上的 awk 警告

  • 772

我正在awk使用字符类发出命令。

cere='^[[:space:]]*([#;!]+|@c|\/\/)[[:space:]]*'

这给出了 awk 警告。

awk: warning: escape sequence `\/' treated as plain `/'

这是需要担心或解决的问题吗？

这是我用于匹配区域的 awk 调用

charcl_ere='^[[:space:]]*([#;!]+|@c|\/\/)[[:space:]]*'

begrec="${charcl_ere}${selec}[[:space:]]*$"
endrec="${charcl_ere}# end of ${fieldval}[[:space:]]*$"

awk -v ccls="$charcl_ere" -v begrsc="$begrec" -v endrsc="$endrec" \
    '$0 ~ begrsc { insc=1; next }
     $0 ~ endrsc { insc=0; print "" }
     insc { sub(ccls,""); print }' "$efile"
awk

1 个回答

  1. Best Answer

    正斜杠字符/在正则表达式中并不特殊。它需要在 awk正则表达式常量中转义，原因与它需要在 sed 表达式中转义（如s/pattern/replacement/1 ）相同；也就是说，因为/被用来分隔正则表达式。所以给定

    $ printf '%s\n' 'foo//bar' 'foo\\baz'
foo//bar
foo\\baz

    然后

    $ printf '%s\n' 'foo//bar' 'foo\\baz' | awk '$0 ~ /o\/\/b/'
foo//bar

    但是，当您将正则表达式作为字符串传递给 awk 时，它会变成动态 regexp。因为它是一个字符串表达式而不是一个正则表达式常量，所以没有分隔符冲突并且/明确地是一个文字字符：

    $ printf '%s\n' 'foo//bar' 'foo\\baz' | awk -v re='o//b' '$0 ~ re'
foo//bar

    这是引起您所询问的警告的情况，即如果您（不必要地）转义斜杠，awk 会提醒您在字符串表达式中，\/与以下内容相同/：

    $ printf '%s\n' 'foo//bar' 'foo\\baz' | awk -v re='o\/\/b' '$0 ~ re'
awk: warning: escape sequence `\/' treated as plain `/'
foo//bar

    尽管您没有询问反斜杠，但可能也值得一提。它们是正则表达式中的特殊字符，需要转义以使它们在正则表达式常量中成为文字：

    $ printf '%s\n' 'foo//bar' 'foo\\baz' | awk '$0 ~ /o\\\\b/'
foo\\baz

    然而这一次，因为转义与分隔符无关，所以在使用动态正则表达式时仍然需要它。更令人困惑的\是，在字符串表达式中也很特殊（\t例如表示 TAB 字符）。因此，当使用动态正则表达式时，每个都\需要转义两次- 一次使其成为字符串文字，再一次使字符串文字成为正则表达式文字：

    $ printf '%s\n' 'foo//bar' 'foo\\baz' | awk -v re='o\\\\\\\\b' '$0 ~ re'
foo\\baz

    最后，如果您使用的是最新版本的 GNU awk（又名 gawk），则可以使用强类型正则表达式常量，即使您从 shell 传递字符串，您也需要在其中转义正斜杠：

    $ printf '%s\n' 'foo//bar' 'foo\\baz' | gawk -v re='@/o\/\/b/' '$0 ~ re'
foo//bar

    1 sed 允许您选择不同的分隔符而不是转义默认分隔符 ex。s:o//b::或\%o//%；据我所知，awk 没有。

    • 0

相关问题