如何显示主机/配置/默认 ssh “配置”？

最近的 openssh 中有一个-G选项，其行为方式与-T服务器端类似。

-G 使 ssh 在评估 Host 和 Match 块后打印其配置并退出。

通过调用ssh -G host，您将获得用于连接到特定主机的选项，这有助于调试ssh_config.

此外，设置更详细的日志级别 ( -vvv) 有助于调试配置解析器。

唯一潜在的缺点-G是它会转储给定目标主机的整个变量集，这对脚本很有用，但在视觉上排序可能有点混乱。

我拼凑了一个又快又脏的 AWK 脚本来满足我的需要；给它一个在Host一行中找到的名称片段，它将打印在.ssh/config文件中找到的配置块。请记住，（1）主机行可以有多个条目，（2）这确实假设配置行将为每个主机块缩进。此外，该脚本不会打印出配置文件中指定的任何全局选项，因为我不想要这些。

#!/usr/bin/gawk -f
#
# Given a ~/.ssh/config file that looks like
#
#    SettingOne foo
#    SettingTwo bar
#
#    Host hostX hostY
#      SettingBlah yes
#      SettingBlurg no
#
#    Host hostZ
#      SettingBlurg no
#
# then "print_ssh_block hostY" will print out the corresponding Setting block,
# which is considerably easier for a human to read than the output of
# "ssh -G hostY".

BEGIN {
    if (ARGC != 2) {
        print "Usage:  print_ssh_block host_fragment"
        exit 1
    }

    # ARGV[0] is the script file itself
    # ARGV[1] is the string fragment to later match in Host lines; we don't
    # want to actually process it as a filename...
    hostfrag = ARGV[1]
    # ...so we replace it with the filename of SSH's config, which we DO want
    # to process with patterns.
    ARGV[1] = ENVIRON["HOME"] "/.ssh/config"
    ARGC = 2
    inHostBlock = 0
}

/#/ { next }

/^[Hh][Oo][Ss][Tt] / {
    # skip $1, since that's "Host"
    for (i = 2; i <= NF; i++) {
        # $i is the individual host; if it matches the script argument,
        # set or clear the flag appropriately
        inHostBlock = ($i ~ hostfrag) ? 1 : 0
        if (inHostBlock) break
    }
}

# When not in a matching host block, skip the indented lines.
inHostBlock == 0 && /^[[:space:]]/ { next  }

# When inside a matching host block, clear the flag as soon as we reach an
# empty line.
inHostBlock == 1 && /^$/  { inHostBlock = 0 }

# When inside a matching host block, print every line we encounter.
inHostBlock == 1          { print }

可以对此进行大约无限的改进。真正的 AWK 大师大概可以用大约五行来编写它。