主页 / server / 问题 / 50310
Accepted
MathewC
Asked: 2009-08-06 04:00:51 +0800 CST

在许多机器上将所有网卡更改为自动/自动

  • 772

由于网络设备发生变化，我可能需要将一堆机器 NIC 设置回自动协商。自动化的最佳方法是什么？我在想通过组策略或 SCCM 推出的 Autoit 编译的 exe。如果您有示例，请发布您的脚本。我不确定我要访问的所有系统都将具有相同的 NIC，因此将所有已知卡重置为自动的东西会很棒。

谢谢！-马修

windows

4 个回答

  1. Best Answer

    这是一个脚本来做你正在寻找的东西。但是，您需要做一些“功课”才能使其正常工作：

    Option Explicit

Const HIVE_HKLM = &H80000002
Const REG_DEVICE_PATH = "SYSTEM\CurrentControlSet\Control\Class\{4D36E972-E325-11CE-BFC1-08002BE10318}"
Const DEBUGGING = 1

Dim objRegistry, arrSubkeys, strSubkey, strComputer, regexpSubkey, strValue, dictDriverChanges, strDriverName

Set dictDriverChanges = CreateObject("Scripting.Dictionary")

' For each given NIC, add an item for the driver description string (case insensitive match) and the value name and value that
' should be set in the NIC's properties
Set dictDriverChanges.Item("Broadcom NetXtreme 57xx Gigabit Controller") = CreateObject("Scripting.Dictionary")
dictDriverChanges.Item("Broadcom NetXtreme 57xx Gigabit Controller").Add "ValueName", "*SpeedDuplex"
dictDriverChanges.Item("Broadcom NetXtreme 57xx Gigabit Controller").Add "Value", "0"


' Pattern to match on subkeys - exactly 4 digits
Set regexpSubkey = new Regexp
regexpSubkey.Global = True
regexpSubkey.Pattern = "\d{4,4}"

' Comptuer to run against. Set to "." for the local computer, or specify the computer-name of a remote machine
strComputer = "."

Set objRegistry = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")

objRegistry.EnumKey HIVE_HKLM, REG_DEVICE_PATH, arrSubkeys

' Did we get back any strSubkeys?
If IsArray(arrSubkeys) Then
    For Each strSubkey In arrSubkeys

        ' Is this a subkey we want to look at
        If regexpSubkey.Execute(strSubkey).Count = 1 Then 
            objRegistry.GetStringValue HIVE_HKLM, REG_DEVICE_PATH & "\" & strSubkey, "DriverDesc", strValue

            ' Loop through all the drivers we know about looking for this driver
            For Each strDriverName in dictDriverChanges
                If UCase(strDriverName) = UCase(strValue) Then
                    If DEBUGGING = 1 Then WScript.Echo "Located driver " & strValue & ". Setting value " & dictDriverChanges.Item(strDriverName).Item("ValueName") & " to " & dictDriverChanges.Item(strDriverName).Item("Value")
                    objRegistry.SetStringValue HIVE_HKLM, REG_DEVICE_PATH & "\" & strSubkey, dictDriverChanges.Item(strDriverName).Item("ValueName"), dictDriverChanges.Item(strDriverName).Item("Value")
                End If
            Next ' strDriverName
        End If

    Next ' strSubkey
End If

    您需要为您要更改的每种 NIC 找到“DriverDesc”值。（查看注册表中每个子项的 REG_DEVICE_PATH 下的注册表，以找到各种 DriverDesc 值）。我在脚本中包含了 Broadcom 57xx 控制器的说明。您需要确定每种 NIC 的注册表值名称和值设置，然后为每种 NIC 添加类似于第 11-15 行的条目。

    这现在针对本地计算机运行。让它在命令行上使用计算机名称并针对远程计算机运行并不难。或者，您可以在每台机器上本地运行它。

    脚本运行后，您需要重新启动计算机才能使更改生效。如果您在 Windows Vista 或 Windows 7 上运行它，请注意它必须在“提升”上下文中运行。（它是在 Windows 7 上开发的，在 Windows XP 上运行良好......）

    那应该可以解决您的问题。

    • 4

  2. 我已经有一段时间没有做过这样的事情了，但我相信改变它的方法会因每个 NIC 卡而异，并且可能会因 NIC 驱动程序的每个版本而异。

    IMO 处理它的最佳方法是在注册表中进行更改。如果您拥有的 PC 型号少于十几种，那么它可能并不难，否则，哎呀。

    • 3

  3. 最好的选择可能是 WMI 脚本。

    这是一个让您入门的示例，它读取网卡信息。为远程计算机设置它们很容易 - 将 computername 变量更改为数组，遍历它们，然后调用 set 方法而不是 get。

    已经有一些关于 serverfault 的 WMI 脚本示例。

    • 1

  4. 我将在这里逆流而上，建议您手动进行更改。将新设备预配置为与旧设备相同的 fubar 设置（100/full 或其他），然后一次通过并重置网络设备和计算机。这是一项非常令人讨厌的工作，但最好确保一切顺利，并且您只需要做一次。

    犯错是人之常情，真正把事情搞砸需要一个脚本。

    • 1

相关问题