Início / ubuntu / Perguntas / 930847
Accepted
Jos
Asked: 2017-07-01 14:34:10 +0800 CST

Nome de arquivo mais longo em um diretório grande

  • 772

Em um grande diretório no meu sistema Ubuntu (> 140.000 arquivos e> 200 subdiretórios), sei que em algum lugar existem dois arquivos com nomes muito longos para serem copiados para uma pasta do Windows (NTFS). Eu tentei e recebi duas mensagens de erro, mas não prestei atenção em quais subpastas os arquivos estavam.

Como posso encontrar os dois arquivos com os nomes mais longos?

command-line

2 respostas

  1. Best Answer

    Acho que a solução do @steeldriver é uma escolha melhor, no entanto, aqui está minha solução alternativa: você pode usar uma combinação de comandos para encontrar exatamente dois (ou mais) nomes de arquivo mais longos.

    find . | awk 'function base(f){sub(".*/", "", f); return f;} \
{print length(base($0)), $0}'| sort -nr | head -2

    a saída seria como:

    length ./path/to/file

    Aqui um exemplo real:

    42 ./path/to/this-file-got-42-character-right-here.txt
31 ./path/to/this-file-got-31-character.txt

    Notas

    findnos dá uma lista de todos os arquivos dentro desse diretório como:

    ./path/to/this-file-got-31-character.txt

    usando awk, adicionamos o tamanho do arquivo ao início de cada linha (é exatamente o tamanho do arquivo, não o caminho):

    31 ./path/to/this-file-got-31-character.txt

    finalmente, classificamos com base no tamanho do arquivo e obtemos as duas primeiras linhas usando head.

    • 10

  2. Com base nos comentários, o que você realmente precisa neste caso é uma lista de todos os arquivos cujos nomes são maiores que um número máximo de caracteres - e felizmente isso é relativamente fácil usando um findregex :

    find $PWD -regextype posix-extended -regex '.*[^/]{255,}$'

    Para um número tão grande de arquivos e diretórios, você provavelmente deseja evitar a classificação - em vez disso, vamos apenas manter um registro contínuo dos nomes de arquivos mais longos e segundos mais longos e seus nomes de caminho completos:

    find $PWD -printf '%p\0' | awk -v RS='\0' '
  {
    # get the length of the basename of the current filepath
    n = split($0,a,"/");
    currlen = length(a[n]);

    if (currlen > l[1]) {
      # bump the current longest to 2nd place
      l[2] = l[1]; p[2] = p[1];
      # store the new 1st place length and pathname
      l[1] = currlen; p[1] = $0;
    }
    else if (currlen > l[2]) {
      # store the new 2st place length and pathname
      l[2] = currlen; p[2] = $0;
    }
  }

  END {
      for (i in l) printf "(%d) %d : %s\n", i, l[i], p[i];
  }'

    ou com GNU awk (que suporta arrays 2D)

    $ find $PWD -printf '%p\0' | gawk -v RS='\0' '
  {
    # get the length of the basename of the current filepath
    n = split($0,a,"/");
    currlen = length(a[n]);

    if (currlen > p[1][1]) {
      # bump the current longest to 2nd place
      p[2][1] = p[1][1]; p[2][2] = p[1][2];
      # store the new 1st place length and pathname
      p[1][1] = currlen; p[1][2] = $0;
    }
    else if (currlen > p[2][1]) {
      # store the new 2st place length and pathname
      p[2][1] = currlen; p[2][2] = $0;
    }
  }

  END {
      for (i in p[1]) printf "(%d) %d : %s\n", i, p[i][1], p[i][2];
  }'
    • 4

relate perguntas