Início / server / Perguntas / 1175834
Accepted
larsks
Asked: 2025-03-20 03:36:05 +0800 CST

Bloco condicional dentro de um bloco condicional no Terraform

  • 772

Estou usando o Terraform para gerenciar uma organização do Github. Temos um módulo padrão "repositório comum" que usamos para garantir que nossos repositórios compartilhem uma configuração comum. Gostaria de adicionar suporte para configurar páginas do GitHub, o que requer suporte para o pageselemento , que se parece com isso:

  pages {
    build_type = "legacy"
    cname = "example.com"
    source {
      branch = "master"
      path   = "/docs"
    }
  }

Tudo é opcional. Em particular, sourceé necessário somente se build_type == "legacy" || build_type == null, e o bloco inteiro pagespode ser omitido. Não consegui descobrir como fazer sourcecondicional, então acabei dividindo isso em dois dynamicblocos assim:

  # There are two `dynamic "pages"` blocks here to account for the fact that `source` is only required
  # if `build_type` is "legacy". The `for_each` at the top of each block will only enable the block when
  # the necessary conditions are met.
  dynamic "pages" {

    # enable this block if `pages` is not null and `build_type` is "legacy" (or null)
    for_each = var.pages == null ? [] : var.pages.build_type == "legacy" || var.pages.build_type == null ? ["enabled"] : []

    content {
      source {
        branch = var.pages.source.branch
        path   = var.pages.source.path
      }

      cname      = var.pages.cname
      build_type = var.pages.build_type
    }
  }

  dynamic "pages" {

    # enable this block if `pages` is not null and `build_type` is "workflow"
    for_each = var.pages == null ? [] : var.pages.build_type == "workflow" ? ["enabled"] : []

    content {
      cname      = var.pages.cname
      build_type = var.pages.build_type
    }
  }

Onde eu defini a pagesvariável no módulo assim:

variable "pages" {
  description = "Configuration for github pages"
  type = object({
    source = optional(object({
      branch = string
      path   = string
    }))
    build_type = optional(string, "legacy")
    cname      = optional(string)
  })
  default = null
}

Existe uma maneira melhor de abordar isso?

terraform

1 respostas

  1. Best Answer

    Sua declaração de variável de entrada já garante que build_typeela mesma não pode ser nula, já que o Terraform usará o valor padrão "legacy"em vez disso, se for o caso. Eu sugeriria também adicionar uma regra de validação para impor que sourcesó pode ser definida se build_typeis "legacy", assim:

    variable "pages" {
  description = "Configuration for github pages"
  type = object({
    source = optional(object({
      branch = string
      path   = string
    }))
    build_type = optional(string, "legacy")
    cname      = optional(string)
  })
  default = null

  validation {
    condition     = var.pages.build_type == "legacy" || var.pages.source == null
    error_message = "The source attribute may be set only when build_type is \"legacy\"."
  }
}

    Com isso em vigor, você pode assumir com segurança que em outro lugar do módulo var.pages.sourcesempre será, nulla menos var.pages.build_typeque seja "legacy", e var.pages.build_typenunca poderá ser null.

    Acredito que nesse ponto o resto do problema se reduz a: declarar o pagesbloco somente se var.pagesnão for nulo, e declarar o sourcebloco dentro dele pagessomente se var.pages.sourcenão for nulo, o que pode ser escrito assim:

      dynamic "pages" {
    for_each = var.pages[*]
    content {
      cname      = pages.value.cname
      build_type = pages.value.build_type

      dynamic "source" {
        for_each = pages.value.source[*]
        content {
          branch = source.value.branch
          path   = source.value.path
        }
      }
    }
  }

    Aplicar o [*]operador a um valor que não é de um tipo de lista, tupla ou conjunto faz com que o Terraform retorne uma tupla com zero ou um elemento, dependendo se o operando é null. Esse tratamento é documentado em Valores Únicos como Listas .

    Por exemplo, se var.pagesfor nulo, então o bloco mais externo acima efetivamente tem for_each = [], enquanto se var.pagesfor não nulo, então for_eaché uma lista de elemento único contendo o mesmo objeto que var.pagescontained, e então isso efetivamente declara zero ou um pagesbloco. O mesmo é verdade para o bloco aninhado dynamic "source".

    Conversa bônus: Esse [*]comportamento de transformar um único valor em uma tupla de zero ou um elemento tem um inverso na forma da onefunção .

    Embora isso não seja diretamente útil neste caso, esses dois recursos geralmente aparecem juntos em um módulo se algo mais no módulo precisar posteriormente se referir a algo que foi previamente transformado em uma tupla usando [*], conforme mostrado em Relação com o operador "Splat" .

    Portanto, acho que vale a pena aprender sobre os dois, pois juntos eles permitem que você se mova livremente entre valores únicos que podem ser nulos e sequências de zero ou um elemento, conforme você usa outros recursos da linguagem Terraform que esperam o oposto do que você está usando no momento.

    Sequências de elementos zero ou um têm essencialmente o mesmo poder expressivo que valores únicos que podem ser nulos, mas muitos recursos da linguagem Terraform priorizam o trabalho com sequências porque podem ser generalizadas para oferecer suporte a números arbitrários de elementos.

    • 1

relate perguntas