Início / dba / Perguntas / 341716
Accepted
Marcello Miorelli
Asked: 2024-08-17 04:47:06 +0800 CST

script para alterar o agendamento de um trabalho, ele precisa encontrar o agendamento associado ao trabalho

  • 772

usando a estratégia de backup do Ola , há um trabalho

databaseBackup - bancos de dados do sistema cheios, como você pode ver na figura abaixo.

esse trabalho está programado para ser executado uma vez por semana, no domingo de manhã.

está tudo bem, já está funcionando há algum tempo.

Agora preciso alterá-lo para funcionar todos os dias.

isso funciona bem usando ssms, criando scripts para a mudança e aplicando-a.

porém, como preciso fazer isso em dezenas de servidores, precisarei de um script que descubra qual é o agendamento, altere-o e reaplique-o no trabalho

Não consegui, mas me pergunto se alguém já fez isso.

insira a descrição da imagem aqui

sql-server

2 respostas

  1. Best Answer

    EDIT: Aprimorado para incluir uma verificação adicional de programações associadas a vários trabalhos.

    SET NOCOUNT ON ;

DECLARE @name sysname ;
DECLARE @freq_type INT ;
DECLARE @schedule_id INT ;

SET @name = 'DatabaseBackup - SYSTEM_DATABASES - FULL' ;

/* 4 = Daily */
SET @freq_type = 4 ;

SELECT @schedule_id = SJS.schedule_id
FROM msdb.dbo.sysjobschedules AS SJS
INNER JOIN msdb.dbo.sysjobs AS SJ
    ON SJ.job_id = SJS.job_id
INNER JOIN msdb.dbo.sysschedules AS SS
    ON SS.schedule_id = SJS.schedule_id
WHERE SJ.[name] = @name
    AND SS.freq_type <> @freq_type ;

IF @@ROWCOUNT = 1
AND NOT EXISTS ( SELECT 1
                 FROM msdb.dbo.sysjobschedules AS SJS
                 WHERE SJS.schedule_id = @schedule_id
                 HAVING COUNT( DISTINCT SJS.job_id ) > 1 )
    BEGIN
        EXEC msdb.dbo.sp_update_schedule 
            @schedule_id = @schedule_id,
            @freq_type = @freq_type ;
    END
ELSE
    BEGIN
        RAISERROR ('Error : did not find a unique Schedule requiring change', 0, 1) ;
    END ;
    • 3 
  2. USE msdb;

GO

declare @jname sysname='DatabaseBackup - SYSTEM_DATABASES - FULL'
declare @sname nvarchar(128)

set @sname=(select s.name from sysjobs j
    inner join sysjobschedules js on j.job_id = js.job_id
    inner join sysschedules s on js.schedule_id = s.schedule_id
    where j.name = @jname)

If len(@sname)>0 
begin
  exec dbo.sp_update_schedule
       @name = @sname,
       @freq_type = 4;
end
else 
 print 'There is not a schedule defined for the job'
    
GO

    MSDN

    • 1

relate perguntas