Início / computer / Perguntas / 1880739
Accepted
Dominique
Asked: 2025-02-18 15:47:59 +0800 CST

Como transformar uma matriz 2x512 no Excel em uma matriz 32x32

  • 772

Tenho um monte de informações, como segue:

 0   1   2   3  4  ...
'0 'C1 '81 '40 '1  ...

(Para sua informação: a segunda linha contém números hexadecimais e estou usando-a 'para que o Excel evite converter valores como '12(que é 18, dezoito) em 12 (doze).

Eu sei sobre funções, como =ToRow()e =ToCol()para converter dados em uma única linha ou coluna. Eu também sei que funções como =Sequence()são capazes de criar uma matriz bidimensional, mas não encontro uma função ToMatrix()ou .ToArray()

Alguém sabe uma maneira fácil de fazer isso no Excel 365?

desde já, obrigado

microsoft-excel

4 respostas

  1. Você pode fazer isso com uma função lambda:

    vá em fórmulas / gerenciador de nomes / novo e digite:

    • nomev_stack
    • refere-se a:=LAMBDA(rng,cols,rows,IF(COLUMNS(rng)>cols,VSTACK(TAKE(rng,rows,cols),v_stack(DROP(rng,0,cols),cols,rows)),rng))

    novo nome forma

    Agora você tem uma função "v_stack" recebendo três argumentos

    • endereço do intervalo que você deseja transformar
    • número de colunas para dividir
    • número de linhas no intervalo original

    decompondo a fórmula:

    =LAMBDA(rng,cols,rows,
 IF(
   COLUMNS(rng)>cols,
   VSTACK(
     TAKE(rng,rows,cols),
     v_stack(DROP(rng,0,cols),cols,rows)),
   rng))

    exemplo de uso da função

    • 6

  2. Não tenho certeza se esta é a ordem que você espera: =WRAPROWS(TOCOL(A1:SR2,,1),32)

    Holandês: =OMLOOP.RIJEN(NAAR.KOLOM(A1:SR2;;1);32)

    Ou: =LET(a,A1:SR2,INDEX(a,1+MOD(SEQUENCE(32,,0),2),SEQUENCE(,32)+INT(SEQUENCE(32,,0,0.5))*32))

    Holandês: =LET(a;A1:SR2;INDEX(a;1+REST(REEKS(32;;0);2),REEKS(;32)+GEHEEL(REEKS(32;;0;0,5))*32))

    • 4
  3. Best Answer

    Com base nesta resposta da techcommunity , embora algo mais simples provavelmente seja possível:

    =LET(
    array, TRANSPOSE(A1:SR2),
    wrapcount, 32,
    totalRows, ROWS(array),
    groups, SEQUENCE(ROUNDUP(totalRows / wrapcount, 0), , 0),
    first, CHOOSEROWS(array, SEQUENCE(wrapcount)),
    TRANSPOSE(REDUCE(
        first,
        DROP(groups, 1),
        LAMBDA(a, b,
            HSTACK(
                a,
                CHOOSEROWS(
                    array,
                    SEQUENCE(
                        MIN(wrapcount, totalRows - b * wrapcount),
                        ,
                        b * wrapcount + 1
                    )))))))

    Resultado

    A única coisa que eu mudei foi adicionado no TRANSPOSE()parâmetro array, já que eles começaram com 2 colunas em vez de 2 linhas. E alterei o wrapcount para 32, conforme sua pergunta. E outra transposição em torno da coisa toda.

    • 3 
  4. =LET(Array, $A$1:$SR$2, 
    Width, 32,
    topRows, WRAPROWS(CHOOSEROWS(Array,1), Width, ""),
    bottomRows, WRAPROWS(CHOOSEROWS(Array,2), Width, ""),
    order, SEQUENCE(QUOTIENT(COLUMNS(Array)-1, Width)+1),
    DROP(
        SORT(
            VSTACK(HSTACK(order, topRows),
                   HSTACK(order+0.5, bottomRows)),
        1),
    0, 1)
)

    Isso envolve as duas linhas na largura especificada e, em seguida, intercala os dois resultados.

    =LET(Array, $A$1:$SR$2,
    Width, 32,
    Height, 2*(1+QUOTIENT(COLUMNS(Array)-1,Width)),
    MAKEARRAY(Height, Width,
        LAMBDA(y, x,
            INDEX(Array,
                2-MOD(y, 2),
                1+MOD(x-1, Width)+Width*QUOTIENT(y-1, 2)
            )
        )
    )
)

    Esta versão apenas cria uma matriz diretamente, percorrendo cada célula de saída por vez.

    • 0

relate perguntas