Início / computer / Perguntas / 1873141
Accepted
Hubert Kauker
Asked: 2025-01-28 02:44:52 +0800 CST

zsh alternar while-loop saída inesperada

  • 772

Estou online ZSH_VERSION=5.9e tenho este script que funciona como esperado:

integer count=3
while true ; do
    echo $count
    (( count-- ))
    if (( count == 0 )) break
done
echo Finally: $count
echo ok

Ele faz a contagem regressiva de 3até 1e então diz: Finally: 0e ok.

Mas vamos substituir o do ... donebloco por um { ... }como este:

integer count=3
while true ; {
    echo $count
    (( count-- ))
    if [[ $count == 0 ]] break
}
echo Finally: $count
echo ok

Não há absolutamente nenhuma mensagem de erro, mas a saída é confusa:

3
Finally: 2
ok
2
Finally: 1
ok
1

Não tenho a mínima ideia do porquê disso, exceto que o analisador tem um problema. Ou estou usando a sintaxe alternativa while-loop errada? Isso acontece quando estou em um shell recém-iniciado.

zsh

2 respostas

  1. Best Answer

    As formas alternativas dos comandos complexos são mais limitadas do que as formas padrão; while truenão é suportado. Dos documentos :

    Para os ifcomandos , whilee until, ... a parte de teste do loop também deve ser delimitada adequadamente, como por [[ ... ]] ou (( ... )), caso contrário o final do teste não será reconhecido.
    ...

    As regras significam que
       if [[ -o ignorebraces ]] {
        print yes
       }
    funciona, mas
       if true { # Does not work!
        print yes
       }
    não funciona, pois o teste não é adequadamente delimitado.
    ...

    whilelist{list2}

    Uma forma alternativa de while. Observe as limitações na forma de listmencionada acima.

    Há várias maneiras de criar uma condição 'adequadamente delimitada' sempre verdadeira. Uma opção:

    integer count=3
while ((1)) {
    echo $count
    if (( ! --count )) break
}
echo Finally: $count
echo ok

    A parte surpreendente é que a while true; {...versão do loop produz qualquer saída, em vez de gerar uma mensagem de erro. Com base em alguns testes limitados, parece que, na ausência de qualquer um dos delimitadores adequados, o analisador simplesmente adiciona tudo após o whileaté o final do script às listcondições de. O loop resultante é provavelmente semelhante a este:

    integer count=3
while true; echo $count; if ((! --count)) break; echo Finally: $count; echo ok
do
done

    Este loop tem vários comandos na condição list, o que é permitido pela whilesintaxe, mas quase nunca usado. Observe que o código de retorno do último comando na lista é o testado pelo while; neste caso, é um echoque retorna com sucesso. É o if...breakque encerra este loop.

    Não encontrei nenhuma documentação que descreva esse comportamento aparente de 'usar tudo até eof'. Você pode ter alguma sorte perguntando aos desenvolvedores na lista de discussão do zsh se isso é intencional, um bug de análise ou uma interpretação errônea do que está acontecendo.

    Editado para adicionar: Parece que houve alguma discussão relacionada a isso na lista de discussão em 2018 e 2024. Um patch para detectar quando não havia uma condição delimitada nunca foi aplicado, em grande parte porque o zshanalisador já imprimirá um erro nesse caso se a SHORT_LOOPSopção não estiver definida (ela é definida por padrão):

    #!/usr/bin/env zsh
unsetopt shortloops
while true; { print $count }

    >> ./tst
./tst:4: parse error near `\n'
    • 3

  2. Obrigado @Gairfowl por me apontar a direção certa. O ponto e vírgula ou a nova linha simplesmente não termina uma lista , mas apenas uma sublista , após a qual mais sublistas podem seguir. Dentro de um { ... }o último ponto e vírgula ou nova linha pode ser omitido, no entanto.

    Quando o zsh analisa a while list do list done, as palavras reservadas do e done encerram as duas listas. Mas quando a while true; { list }é visto, o analisador toma true;como primeira sublista, { list }como segunda, e todos os comandos subsequentes em linhas separadas como sublistas adicionais, também, até o EOF. Acabamos tendo uma lista maior do que o pretendido para a condição de loop, e um corpo vazio do loop. Obviamente, um corpo vazio é permitido, então eu diria que esse comportamento é intencional, no geral.

    Para resumir, as seguintes construções estão funcionando conforme o esperado:

    while true; do
done

while { true } do
done

while { true; } {
}

while { true } {
}

while (( 1 )) do
done

while (( 1 )); do
done

while (( 1 )) {
}

    Mas o seguinte NÃO está funcionando:

    while (( 1 )) ; {
}

    Ele tem o mesmo problema de "ganância" que while true; { ... }.

    • 2

relate perguntas