Como posso exibir o nome da pasta do e-mail aberto no momento?

Na exibição da lista de e-mails do Outlook, você pode adicionar uma coluna extra "Na pasta".

Como fazer isso é explicado neste post.

Copiado do post post:
Inicie o Outlook >> Exibições >> Alterar Exibição >> Gerenciar Exibição, selecione Configurações de exibição atuais >> Modificar >> Coluna, então adicione a coluna "Na Pasta" novamente. Clique em OK três vezes e reinicie o cliente Outlook, você deve conseguir ver a coluna fixa Na Pasta quando fizer outra pesquisa no Outlook.

Página relacionada da Microsoft .

Para mostrar a pasta do e-mail selecionado ou aberto no momento, você pode usar a seguinte macro VBA:

Option Explicit

Public Sub ShowMailItemFolder()
    Dim exp As Explorer
    Dim sel As Selection
    Dim please As String
    Dim s As String
    Dim mi As Outlook.mailItem
    Set exp = Application.ActiveExplorer

    If exp Is Nothing Then
        MsgBox "No Explorer active!"
    Else
        Set sel = exp.Selection

        please = " Please select one Mail!"
        If sel Is Nothing Then
            MsgBox "No Selection!" & please
        ElseIf sel.count > 1 Then
            MsgBox "Multiple selection!" & please
        ElseIf sel.count < 1 Then
            MsgBox "No Selection!" & please
        ElseIf sel.Item(1).Class <> olMail Then
            MsgBox "No Mail selected!" & please
        Else
            Set mi = sel.Item(1)

            If mi Is Nothing Then
                MsgBox "No mail selected!"
            Else
                MsgBox mi.Parent.FolderPath
            End If
        End If
    End If
End Sub

Defina um botão de menu para iniciar esta macro via clique do mouse. Ele abrirá uma MessageBox e exibirá a pasta MailItem.