Início / computer / Perguntas / 1857669
Accepted
CorlissExcelling
Asked: 2024-10-04 05:29:03 +0800 CST

Como posso classificar uma função de filtro usando um arranjo de colunas personalizado e não ter cabeçalhos incluídos na classificação?

  • 772

Consegui fazer essa fórmula funcionar para o filtro em que tenho colunas AEe AFas selecionei.

Quando tentei adicionar uma parte de classificação à fórmula, ela misturou os cabeçalhos e a fórmula misturou os cabeçalhos com os dados listados.

Original:

=FILTER(CHOOSE({1,2},AF:AF,AE:AE),AE:AE>0)

Classificação em ordem crescente para a 1ª coluna:

=SORT(FILTER(CHOOSE({1,2},AF:AF,AE:AE),AE:AE>0),1,1)

Existe uma maneira de não incluir os cabeçalhos na classificação?

Observação : o conjunto de dados não é uma tabela e não posso transformá-lo em uma tabela porque o cliente não quer que os dados brutos sejam transformados.

Recurso para colunas personalizadas:

atualização: 04/10/24 Tentei usar a parte DROP conforme sugerido, mas recebi o erro NAME?, então a versão que tenho não me permite usar DROP. - Obrigado.

microsoft-excel

2 respostas

  1. Tentar:

    SORT(DROP(FILTER(CHOOSE({1,2},AF:AF,AE:AE),AE:AE>0),1),1,1)
    • 1
  2. Best Answer

    Como, de acordo com a postagem do OP, eles não têm acesso à DROP()função, então poderiam usar a seguinte fórmula também para obter o resultado desejado:

    insira a descrição da imagem aqui

    =LET(
     _Vals, A:A,
     _LastRow, MATCH(2,1/(_Vals<>"")),
     _Nvals, A2:INDEX(_Vals,_LastRow),
     _Name, F2:INDEX(F:F,_LastRow),
     SORT(FILTER(CHOOSE({1,2},_Name,_Nvals),_Nvals>0)))

    Então, com relação aos intervalos por OP:

    =LET(
     _A, AE:AE,
     _LastRow, MATCH(2,1/(_A<>"")),
     _NA, AE2:INDEX(_A,_LastRow),
     _B, AF2:INDEX(AF:AF,_LastRow),
     SORT(FILTER(CHOOSE({1,2},_B,_A),_A>0)))

    Observe que a fórmula acima é baseada na coluna AEcuja última célula não vazia foi tomada como a última linha base para todas as outras colunas incluídas.

    Ou, você poderia usar algo assim também:

    =LET(
     a, FILTER(CHOOSE({1,2},AF:AF,AE:AE),AE:AE>0),
     SORT(INDEX(a, SEQUENCE(ROWS(a)-1,,2),{1,2})))

    insira a descrição da imagem aqui

    • 0

relate perguntas